PL/SQL Challenge 每日一题：2014-3-5 在声明部分抛出的异常

newkid · 发表于 2014-3-7 04:17

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正)，其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

以往旧题索引：
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处：
http://www.plsqlchallenge.com/

作者：Steven Feuerstein

运行环境：SQLPLUS, SERVEROUTPUT已打开
注：本题给出答案时候要求给予简要说明才能得到奖品

哪些选项创建了一个名为PLCH_FUNC的函数，使得这个代码执行之后:

DECLARE
l_value VARCHAR2 (30) := 'This is your brain on music';
BEGIN
DBMS_OUTPUT.put_line (plch_func (l_value));
END;
/

会显示"This is your brain on music" ?

(A)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
l_return VARCHAR2 (10) := UPPER (value_in);
BEGIN
RETURN l_return;
EXCEPTION
WHEN OTHERS
THEN
   RETURN value_in;
END;
/

(B)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
l_return VARCHAR2 (10);
BEGIN
l_return := UPPER (value_in);
RETURN l_return;
EXCEPTION
WHEN OTHERS
THEN
   RETURN value_in;
END;
/

(C)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
BEGIN
IF LENGTH (value_in) > 10
THEN
   RETURN value_in;
ELSE
   RETURN UPPER (value_in);
END IF;
END;
/

(D)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
l_return VARCHAR2 (10);

PROCEDURE initialize
IS
BEGIN
   l_return := UPPER (value_in);
END;
BEGIN
initialize;
RETURN l_return;
EXCEPTION
WHEN OTHERS
THEN
   RETURN value_in;
END;
/

(E)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
l_return VARCHAR2 (10);

PROCEDURE initialize
IS
BEGIN
   l_return := UPPER (value_in);
END;
BEGIN
RETURN l_return;
EXCEPTION
WHEN OTHERS
THEN
   RETURN value_in;
END;
/

(F)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
BEGIN
DECLARE
   l_return VARCHAR2 (10) := UPPER (value_in);
BEGIN
   RETURN l_return;
END;
EXCEPTION
WHEN OTHERS
THEN
   RETURN value_in;
END;
/

(G)
CREATE OR REPLACE FUNCTION plch_func (value_in IN VARCHAR2)
RETURN VARCHAR2
IS
BEGIN
DECLARE
   l_return VARCHAR2 (10) := UPPER (value_in);
BEGIN
   RETURN l_return;
EXCEPTION
   WHEN OTHERS
   THEN
      RETURN value_in;
END;
END;
/

lee253654522 · 发表于 2014-3-7 08:41

A  错误。由于l_return长度为10，会抛出character string buffer too small的异常，因为在声明块中，因此不会被EXCEPTION捕获。
B  正确。抛出异常的语句为l_return := UPPER (value_in)，可以被EXCEPTION捕获，返回value_in
C  正确。判断LENGTH(value_in)>10，因此直接返回value_in
D  正确。在执行initialize中的l_return := UPPER (value_in)时抛出异常，但是可以被EXCEPTION捕获，返回value_in
E  错误。l_return没有在函数中赋值，返回默认值null。
F  正确。与A不同的是将声明语句包含在BEGIN语句块中，可以被EXCEPTION捕获。
G  错误。仍然会抛出character string buffer too small的异常，原因是在声明语句的BEGIN块中没有EXCEPTION。
因此，答案为B C D F

liwei9902 · 发表于 2014-3-7 11:59

lee253654522 发表于 2014-3-7 08:41
A 错误。由于l_return长度为10，会抛出character string buffer too small的异常，因为在声明块中，因此不 ...

厉害

newkid · 发表于 2014-3-8 04:49

答案BCDF, 2楼得奖。

A: 这个选项在声明部分对字符串赋值，但是本地变量太小了，所以异常未经处理被传播到函数外面，没有任何东西被显示。
B: 我将赋值转移到执行部分，所以错误被抛出（因为本地变量太小），然后被WHEN OTHERS捕获并处理。
C: （不推荐）
这样也行——它显式地检查输入字符串的长度来查看是否太大。但这不是最好的方法。让PL/SQL的异常处理这种事。
D: （推荐）
我将赋值转移到执行部分——看起来是这样。我创建了一个内嵌过程来包含所有初始化相关的代码（此处仅有一个赋值语句），所以错误被抛出（因为本地变量太小），然后被WHEN OTHERS捕获并处理。
E: 写在这里是为了提醒你这是一个常见错误（至少发生在我身上是常见的

）将代码转移到一个内嵌子程序之后忘记调用了！
这个版本永远返回NULL。
F: 在这个选项中我试图在声明部分进行赋值，但它是处于一个内嵌的块中，所以外层的块能够捕获并处理异常。
G: 在这个选项中错误发生在嵌套块的声明部分，而且异常处理器也附在这个内嵌块，而不是外层的块。结果，异常未经处理就离开了外层块。