PL/SQL CHALLENGE 每日一题

newkid

2011-10-17 答案 CD
对记录类型不能使用IS NOT NULL判断，否则会出现：
PLS-00306: wrong number or types of arguments in call to 'IS NOT NULL'
这导致AB出现异常。
Steven Feuerstein建议你采用D的做法以便于重用代码。

2011-10-18: TO_CHAR格式
作者：        Steven Feuerstein
难度：中

我的经理叫我写一个函数，这个函数接受一个正整数并返回相应的序数(比如，2->2nd,  145->145th), 这个序数是一个字符串。这个函数只接受1和50,000之间的整数。


下列的哪些选项实现了函数plch_n_to_nth, 从而使得它满足上述需求，在下列块被执行之后：

BEGIN
   DBMS_OUTPUT.put_line (plch_n_to_nth (1));
   DBMS_OUTPUT.put_line (plch_n_to_nth (8));
   DBMS_OUTPUT.put_line (plch_n_to_nth (256));
   DBMS_OUTPUT.put_line (plch_n_to_nth (25763));
END;
/

我能见到如下输出：

1st
8th
256th
25763rd

英语序数词定义可参见：
http://en.wikipedia.org/wiki/English_numerals#Ordinal_numbers

(A)
CREATE OR REPLACE FUNCTION plch_n_to_nth (n_in IN INTEGER)
   RETURN VARCHAR2
IS
BEGIN
   RETURN TO_CHAR (n_in, '9999th');
END;
/

(B)
CREATE OR REPLACE FUNCTION plch_n_to_nth (n_in IN INTEGER)
   RETURN VARCHAR2
IS
BEGIN
   RETURN LOWER (
             TO_CHAR (
                TO_DATE ('1-1-' || n_in, 'dd-mm-yyyy')
              ,  'FMYYYYth'));
END;
/

(C)
CREATE OR REPLACE FUNCTION plch_n_to_nth (n_in IN INTEGER)
   RETURN VARCHAR2
IS
BEGIN
   RETURN LOWER (
             TO_CHAR (
                TO_DATE ('1-1-2011 ' || n_in
                       ,  'dd-mm-yyyy SSSSS')
              ,  'FMSSSSSth'));
END;
/

(D)
CREATE OR REPLACE FUNCTION plch_n_to_nth (
   n_in IN INTEGER)
   RETURN VARCHAR2
IS
   c_last_digit   CONSTANT PLS_INTEGER
                              := MOD (n_in, 10) ;
   c_tens_digit   CONSTANT CHAR (1)
      := SUBSTR ('0' || TO_CHAR (n_in), -2, 1) ;
BEGIN
   RETURN    TO_CHAR (n_in)
          || CASE
                WHEN c_tens_digit = '1' THEN 'th'
                WHEN c_last_digit = 1 THEN 'st'
                WHEN c_last_digit = 2 THEN 'nd'
                WHEN c_last_digit = 3 THEN 'rd'
                ELSE 'th'
             END;
END plch_n_to_nth;
/

gyhgood

TO_CHAR 用法真是太多了

hanaka

测试结果
2011-10-18： CD
压根没想到这个方法

newkid

2011-10-19 答案：D
(A)
这个选项的结果是：
100
200
ERROR
这是因为我关闭C1之后，C2也会被关闭，所以第三个FETCH会抛出"ORA-01001: invalid cursor"异常。

(B)
同上，只要C1,C2其中一个被关闭，另一个就相应被关闭。

(C)
这个选项的结果是：
100
200
300
ERROR

既然我在三个FETCH结束前没有关闭游标，我就能看到100-300。但是随后我关闭了C1, 而且还试图关闭C2。C1一旦被关闭，C2也自动被关闭，因此假如试图再关闭C2就会报"ORA-01001: invalid cursor"错误。

(D)正确

======================================
2011-10-20 %TYPE的使用
作者：Steven Feuerstein
难度：中

我创建了这些类型和表：

CREATE TYPE plch_food_t AS OBJECT (name VARCHAR2 (100));
/

CREATE or replace TYPE plch_food_nt
   IS TABLE OF VARCHAR2 (100)
/

CREATE TABLE plch_food (name VARCHAR2 (100))
/

CREATE OR REPLACE PACKAGE plch_pkg
IS
   TYPE food_rt IS RECORD (name VARCHAR2 (100));
END;
/

下面的哪些选项在执行之后将会显示"Brussels Sprouts"?

(A)
DECLARE
   l_var   plch_food.name%TYPE := 'Brussels Sprouts';
BEGIN
   DBMS_OUTPUT.put_line (l_var);
END;
/

(B)
DECLARE
   l_var   plch_food_nt%TYPE := 'Brussels Sprouts';
BEGIN
   DBMS_OUTPUT.put_line (l_var);
END;
/

(C)
DECLARE
   l_var   plch_food_t.name%TYPE := 'Brussels Sprouts';
BEGIN
   DBMS_OUTPUT.put_line (l_var);
END;
/

(D)
DECLARE
   l_var   plch_pkg.food_rt.name%TYPE := 'Brussels Sprouts';
BEGIN
   DBMS_OUTPUT.put_line (l_var);
END;
/

hanaka

2011-10-20   A

sohay

D为什么不行呢？
BC的提示说“%type用于变量、列、字段或属性”，我试过了变量、列，确实可以。按说，plch_pkg.food_rt.name是属性，应该可以啊？

ccceleven

  MARK  好 东西

susie0409

需要多加练习了。。。。。

newkid

2011-10-20 答案 A

D为什么不行？你不能对记录类型直接使用%TYPE, 必须先声明一个基于该记录类型的变量，然后对这个变量使用%TYPE:

DECLARE
   l_food   plch_pkg.food_rt;
   l_var    l_food.name%TYPE := 'Brussels Sprouts';
BEGIN
   DBMS_OUTPUT.put_line (l_var);
END;
/

=================================================
2011-10-21:
作者：        Steven Feuerstein
难度：中

下列的哪些程序块在执行之后会显示："Trapped!"

注意：当你试图把字符串 "13-DEC-2004 6:56 PM" 使用掩码 "DD-MON-YYYY HH:MI:SS" 转换成日期型时，Oracle 会抛出 ORA-01858 错误。

(A)
DECLARE
   e1   EXCEPTION;
   PRAGMA EXCEPTION_INIT (e1, -1858);
BEGIN
   DBMS_OUTPUT.put_line (
      TO_DATE ('13-DEC-2004 6:56 PM'
             ,  'DD-MON-YYYY HH:MI:SS'));
EXCEPTION
   WHEN e1
   THEN
      DBMS_OUTPUT.put_line ('Trapped!');
END;
/

(B)
DECLARE
   e1   EXCEPTION;
   PRAGMA EXCEPTION_INIT (e1, -1858);
BEGIN
   DECLARE
      e2   EXCEPTION;
      PRAGMA EXCEPTION_INIT (e2, -1858);
   BEGIN
      DBMS_OUTPUT.put_line (
         TO_DATE ('13-DEC-2004 6:56 PM'
                ,  'DD-MON-YYYY HH:MI:SS'));
   END;
EXCEPTION
   WHEN e1
   THEN
      DBMS_OUTPUT.put_line ('Trapped!');
END;
/


(C)
DECLARE
   e1   EXCEPTION;
   PRAGMA EXCEPTION_INIT (e1, -1858);
BEGIN
   DECLARE
      e2   EXCEPTION;
      PRAGMA EXCEPTION_INIT (e2, -1858);
   BEGIN
      DBMS_OUTPUT.put_line (
         TO_DATE ('13-DEC-2004 6:56 PM'
                ,  'DD-MON-YYYY HH:MI:SS'));
   END;
EXCEPTION
   WHEN e2
   THEN
      DBMS_OUTPUT.put_line ('Trapped!');
END;
/



(D)
DECLARE
   e1   EXCEPTION;
BEGIN
   DECLARE
      PRAGMA EXCEPTION_INIT (e1, -1858);
   BEGIN
      DBMS_OUTPUT.put_line (
         TO_DATE ('13-DEC-2004 6:56 PM'
                ,  'DD-MON-YYYY HH:MI:SS'));
   END;
EXCEPTION
   WHEN e1
   THEN
      DBMS_OUTPUT.put_line ('Trapped!');
END;
/

gyhgood

我猜全不对，没看懂E1有啥用。。。。