PL/SQL CHALLENGE 每日一题

sohay

AB

gyhgood

BE

gyhgood

验证完我的心拔凉拔凉的。。。。。。

newkid

2011-11-1 答案ABD, B是最佳答案，注意D在某些情况下可能出现误差。
==================================================================
2011-11-2 游标和管道函数
作者：Steven Feuerstein
难度：高

我创建了这张表并填入数据：
CREATE TABLE plch_parts
(
   partnum    INTEGER PRIMARY KEY
, partname   VARCHAR2 (100) UNIQUE
)
/

BEGIN
   INSERT INTO plch_parts VALUES (1, 'Mouse');
   INSERT INTO plch_parts VALUES (100, 'Keyboard');
   INSERT INTO plch_parts VALUES (500, 'Monitor');
   COMMIT;
END;
/

我建立了如下的嵌套表类型和包说明：

CREATE OR REPLACE TYPE numbers_t IS TABLE OF NUMBER;
/

CREATE OR REPLACE PACKAGE plch_pipeline
IS
   CURSOR refcur_c
   IS
      SELECT line FROM user_source;

   TYPE refcur_t IS REF CURSOR
      RETURN refcur_c%ROWTYPE;

   FUNCTION double_values (dataset refcur_t)
      RETURN numbers_t
      PIPELINED;
END plch_pipeline;
/

下列的选项中哪些实现了包体，从而使得这个查询执行之后：
SELECT *
  FROM TABLE (plch_pipeline.double_values (
                CURSOR (SELECT line
                          FROM user_source
                         WHERE name = 'PLCH_PIPELINE'
                           AND type = 'PACKAGE'
                           AND line <= 3
                         ORDER BY line)))
/

这三行会显示出来：
2
4
6


(A)
CREATE OR REPLACE PACKAGE BODY plch_pipeline
IS
   FUNCTION double_values (dataset refcur_t)
      RETURN numbers_t PIPELINED
   IS
      l_number   NUMBER;
   BEGIN
      LOOP
         FETCH dataset INTO l_number;
         EXIT WHEN dataset%NOTFOUND;

         UPDATE plch_parts SET partnum = partnum;
            
         PIPE ROW (l_number * 2);
      END LOOP;
      CLOSE dataset;
      RETURN;
   END;
END plch_pipeline;
/


(B)
CREATE OR REPLACE PACKAGE BODY plch_pipeline
IS
   FUNCTION double_values (dataset refcur_t)
      RETURN numbers_t PIPELINED
   IS
      PRAGMA AUTONOMOUS_TRANSACTION;
      l_number   NUMBER;
   BEGIN
      LOOP
         FETCH dataset INTO l_number;
         EXIT WHEN dataset%NOTFOUND;

         UPDATE plch_parts SET partnum = partnum;

         PIPE ROW (l_number * 2);
      END LOOP;
      CLOSE dataset;
      RETURN;
   END;
END plch_pipeline;
/

(C)
CREATE OR REPLACE PACKAGE BODY plch_pipeline
IS
   FUNCTION double_values (dataset refcur_t)
      RETURN numbers_t PIPELINED
   IS
      PRAGMA AUTONOMOUS_TRANSACTION;
      l_number   NUMBER;
   BEGIN
      LOOP
         FETCH dataset INTO l_number;
         EXIT WHEN dataset%NOTFOUND;

         UPDATE plch_parts SET partnum = partnum;

         PIPE ROW (l_number * 2);
      END LOOP;
      CLOSE dataset;

      COMMIT;
      RETURN;
   END;
END plch_pipeline;
/

(D)
CREATE OR REPLACE PACKAGE BODY plch_pipeline
IS
   FUNCTION double_values (dataset refcur_t)
      RETURN numbers_t PIPELINED
   IS
      PRAGMA AUTONOMOUS_TRANSACTION;
      l_number   NUMBER;
   BEGIN
      LOOP
         FETCH dataset INTO l_number;
         EXIT WHEN dataset%NOTFOUND;

         UPDATE plch_parts SET partnum = partnum;
         COMMIT;
         
         PIPE ROW (l_number * 2);
      END LOOP;
      CLOSE dataset;
      RETURN;
   END;
END plch_pipeline;
/

jboracle1981

106#楼
(A)肯定是错误的，select语句不能进行dml操作，需要自治事务才可以
感觉(B)(C)(D)都对

jboracle1981

测试之后真是心拔凉拔凉的
基础太不扎实了

gyhgood

题越来越有深度了。。。。

newkid

2011-11-2 答案D.
A: 在SQL中调用的函数不能有DML, 除非是自治事务；
B: 虽然用了自治事务，但是在返回之前（PIPE ROW 就是返回一行数据）必须提交或回滚这个事务；
C: 虽然用了自治事务而且有COMMIT, 但是位置不对，COMMIT放在循环外面，这样在返回（PIPE ROW）之前还是没有提交。

==================================================================
2011-11-3 触发器
作者：Steven Feuerstein
难度：低

我们维护一张客户表，这张表的内容在周六和周日不允许修改。这就是客户表：
CREATE TABLE plch_customers
(
   custnum    INTEGER
, custname   VARCHAR2 (100)
)

我需要创建一个触发器来阻止周末对这张表的任何插入、修改和删除。我写了这些代码：

CREATE OR REPLACE TRIGGER plch_customers_maint_trg
   /*TEXT*/
DECLARE
BEGIN
   IF TO_CHAR (SYSDATE, 'DY', 'NLS_DATE_LANGUAGE=ENGLISH')
         IN ('SAT', 'SUN')
   THEN
      RAISE_APPLICATION_ERROR (-20000
          , 'Customers maintained Monday-Friday only.');
   END IF;
END;
/

哪些选项可用来取代文中的/*TEXT*/, 使得这个触发器不允许周末对plch_customers表执行任何DML操作，并且每个语句只触发一次？

(A)
BEFORE UPDATE ON plch_customers FOR EACH ROW
BEFORE INSERT ON plch_customers FOR EACH ROW
BEFORE DELETE ON plch_customers FOR EACH ROW

(B)
BEFORE UPDATE ON plch_customers
BEFORE INSERT ON plch_customers
BEFORE DELETE ON plch_customers

(C)
BEFORE UPDATE, INSERT OR DELETE ON plch_customers

(D)
BEFORE UPDATE OR INSERT OR DELETE ON plch_customers FOR EACH ROW


(E)
BEFORE UPDATE OR INSERT OR DELETE ON plch_customers

sohay

选E
ABC语法不对，D是每行都会触发

hotdog04

newkid 发表于 2011-11-2 23:09
10-31答案BD. 对于非密集型的COLLECTION访问不能从1开始，而是要用FIRST方法。访问不存在的元素会引发NO_DA ...

DE