有奖活动：PL/SQL Challenge 每日一题：2012-4-30 对象的自定义构造函数

newkid

最快答对且答案未经编辑的puber将获得彩蛋章一枚(编辑过的答案不算)，其他会员如果提供有价值的分析、讨论也可获得彩蛋章一枚。

以往旧题索引：
http://www.itpub.net/thread-1499223-1-1.html

原始出处：
http://www.plsqlchallenge.com/

作者：Steven Feuerstein
难度：高


我创建了如下的对象类型来帮我计算PL/SQL代码的执行时间：

CREATE OR REPLACE TYPE plch_timer_t AS OBJECT
(
   timer_name VARCHAR2 (2000),
   start_time INTEGER,
   MEMBER PROCEDURE start_timer,
   MEMBER PROCEDURE stop_timer
);
/

CREATE OR REPLACE TYPE BODY plch_timer_t
AS
   MEMBER PROCEDURE start_timer
   IS
   BEGIN
      SELF.start_time := DBMS_UTILITY.get_time;
   END;

   MEMBER PROCEDURE stop_timer
   IS
   BEGIN
      DBMS_OUTPUT.put_line (
         DBMS_UTILITY.get_time - start_time);
   END;
END;
/

有了这个类型定义，我可以用如下方法来使用它：
DECLARE
   l_timer plch_timer_t :=
      plch_timer_t ('plch_proc performance', NULL);

   PROCEDURE plch_proc IS
   BEGIN
      null;
   END;
BEGIN
   l_timer.start_timer;
   plch_proc;
   l_timer.stop_timer;
END;
/

但我不想在调用timer_t构造函数的时候传递NULL参数；那是start_timer过程里面的设置。哪些选项提供了修改plch_timer_t定义的方法，从而使得下列代码块能够成功执行？

DECLARE
   l_timer plch_timer_t :=
      plch_timer_t ('plch_proc performance');

   PROCEDURE plch_proc IS
   BEGIN
      null;
   END;
BEGIN
   l_timer.start_timer;
   plch_proc;
   l_timer.stop_timer;
END;
/

(A)
CREATE OR REPLACE TYPE plch_timer_t AS OBJECT
(
   timer_name VARCHAR2 (2000),
   PRIVATE start_time INTEGER,
   MEMBER PROCEDURE start_timer,
   MEMBER PROCEDURE stop_timer
);
/

(B)
CREATE OR REPLACE TYPE plch_timer_t AS OBJECT
(
   timer_name VARCHAR2 (2000),
   start_time INTEGER DEFAULT NULL,
   MEMBER PROCEDURE start_timer,
   MEMBER PROCEDURE stop_timer
);
/

(C)
把这个加入到类型规格(type specification)定义：
CONSTRUCTOR FUNCTION plch_timer_t (
   self            IN OUT plch_timer_t,
   timer_name_in   IN     VARCHAR2)
   RETURN SELF AS RESULT,

把这个加入到类型体(type body)定义：
CONSTRUCTOR FUNCTION plch_timer_t (
   self            IN OUT plch_timer_t,
   timer_name_in   IN     VARCHAR2)
   RETURN SELF AS RESULT
IS
BEGIN
   self.timer_name := timer_name_in;
   RETURN;
END;

(D)
把这个成员函数加入到类型规格(type specification)定义：
MEMBER FUNCTION plch_timer_at (timer_name_in IN VARCHAR2)
      RETURN SELF AS RESULT

把这个加入到类型体(type body)定义：
MEMBER FUNCTION plch_timer_t (timer_name_in IN VARCHAR2)
   RETURN SELF AS RESULT
IS
BEGIN
   self.timer_name := timer_name_in;
   RETURN;
END;

arron刘

偶不会，。，。。。。偶想要彩蛋蛋

lwhjava

C

周应侯

arron刘 发表于 2012-5-2 09:21
偶不会，。，。。。。偶想要彩蛋蛋

把newkid的帖子用心看一遍，敲一遍，就会了~

newkid

3楼答对了，答案C.

A: ORACLE不支持私有(private)属性的定义。这个语句将会报错：
ORA-06545: PL/SQL: compilation error - compilation aborted
ORA-06550: line 4, column 23:
PLS-00103: Encountered the symbol "INTEGER" when expecting one of the following:

B:对象属性不允许指定缺省值。这个选项将会报错：
PLS-00363: expression 'START_TIME' cannot be used as an assignment target

C: 是的，你可以定义自己的构造函数，作为ORACLE自动提供的构造函数的补充，这个选项使用了正确的语法。
D: 如果你想创建一个自定义的构造函数，你必须使用CONSTRUCTOR关键字，它不能定义为类型的成员函数。

Oracle PL/SQL支持所有常见的数据类型，例如字符串，数值和日期，此外还加入了一些它自己特有的数据类型，包括记录和集合。

构造函数是你对一个对象类型的实例或者一个集合进行初始化的时候调用的方法（函数）; 它的名字永远和类型名字相同。如果你未经初始化就试图使用它们，ORACLE会抛出 "ORA-06530: Reference to uninitialized composite" 错误。

当你初始化一个对象类型的实例的时候，你必须为每个属性提供一个表达式。当你初始化一个嵌套表或可变数组的时候，你可以不为数组提供任何的表达式（数组元素）。


ORACLE为每个类型定义了一个构造函数；你也可以定义自己定制的构造函数。通常这样做的目的是为了使得你不必在初始化类型的时候为每个属性提供一个表达式。

在面向对象语言中，自定义构造函数是一个很方便的功能。在ORACLE实现方法中，它们显得格外重要，因为ORACLE还不支持私有属性。这使得缺省的构造函数要求为所有的属性提供一个值，即使是那些用户永远不会直接打交道的属性(这种属性的值由对象类型自己维护)。

ORACLE提供的缺省构造函数对应每个属性都有一个参数，返回的是对象类型的一个实例。当你定义自己的构造函数时，你可以修改参数列表。通常你这样做是为了“隐藏”该类型用户不应该自己设置值的那些属性。

ORACLE不支持在对象类型中的私有属性或私有方法，这使得所有东西都是“公共”的，即使是由类型的方法来设置和操纵值的那些属性。一个自定义构造函数至少使得开发者可以不必为那些本来应该私有的属性赋值。

自定义构造函数头的语法是：

CONSTRUCTOR FUNCTION type_name (
      SELF IN OUT timer_t,
      other_parameters
)
RETURN SELF AS RESULT

xtzhhg

不会说了会被人骂的。