在 Visual Basic .NET 中实现后台进程

keaide

使用图表通常能够很好地了解不同组件（尤其是不同线程上的组件）之间的交互。Microsoft® Visio® 支持创建 UML（通用建模语言）图表，对理解很有帮助。

以下是说明 UI、Worker 对象和 Controller 之间事件流的 UML 序列图表。此图表假设不存在任何取消操作请求。Worker 和 Controller 对象下面重叠在垂直线上的垂直活动栏突出了辅助线程上运行的代码。其他所有代码都在 UI 线程上运行。



图 2：说明进程流的序列图表

使用 UML 活动图表也可以查看事件流。这种图表形式的着重点在于任务而不是对象，因此其中显示了发生的一系列步骤以及各步骤之间的流程。我们很容易看出 UI 代码如何停留在左侧的线程中，而 Worker 对象如何在右侧的线程上工作。Worker 对象在其他线程中运行之前和运行之后可以直接由 UI 使用，以便初始化值，然后再检索结果。

keaide

图 3：显示进程流的活动图表

使用这样的图表可以帮助我们找出后台线程处于激活状态时，UI 与辅助线程（或反过来）无意中进行直接交互的位置。任何这样的交互都需要额外地进行编码，以避免出现可能使应用程序不稳定的错误。理想状态下，这种交互通过 Controller 组件来实现，我们可以在其中包含所有编码，使交互安全进行。

下图说明了 UI 发出取消请求时的事件序列。



图 4：显示取消请求的序列图表

请注意，取消请求从 UI 发送到 Controller，然后 Worker 线程与 Controller 进行核实，确定是否发生了取消请求。UI 和 Controller 都不会强制辅助代码终止，而是允许辅助代码自己正常安全地终止。

keaide

架构设计
要实现我们讨论的行为，显然需要实现 Controller 类。为了使此架构能够在多数方案中应用，我们还会定义一些正式接口，可以由 Controller 在与 UI（或客户端）和辅助线程交互时使用。

通过为客户端和辅助线程定义正式接口，我们可以在不同的情况下使用相同的 Controller 对象，还可以根据需要使用不同的 UI 要求和不同的 Worker 对象。

下面的 UML 类图表显示了 Controller 类以及 IClient 和 IWorker 接口。它还显示了 IController 接口，辅助代码将通过它与 Controller 对象交互。

keaide

IClient 接口定义的方法将由 Controller 对象调用，用于向客户端 UI 通报 Worker 的开始时间、结束时间和任何中间状态消息。它还包含一个指示辅助代码失败的方法。

多数情况下，我们可以将这些方法作为由 Controller 对象发出而由 UI 处理的事件来实现。但是，从辅助线程发出事件然后由 UI 线程正确处理并非易事，因而我们将其作为一组方法来进行实现。

使控制器代码（在辅助代码上运行）调用 UI 中的这些方法并由 UI 线程进行处理，这样相对要简单得多。

同样，IWorker 接口定义了由 Controller 对象调用的、使其可以与辅助代码交互的方法。使用 Initialize 方法可以为辅助代码提供对 Controller 对象的引用，而使用 Start 方法可以启动后台线程上的操作。

由于线程的工作方式，Start 方法无法包含任何参数。启动新线程时，必须将不接受任何参数的方法的地址传递给线程。

请注意，IWorker 接口中不存在 Cancel 或 Stop 方法。我们不能强制辅助代码停止，同时也没有这个必要；但是辅助代码可以使用 IController 接口询问 Controller 对象是否存在取消请求。

keaide

IController 接口定义了辅助代码可以在 Controller 对象上调用的方法。它允许辅助代码检查 Running 标志。如果存在取消请求，Running 标志即为 False。它还允许辅助代码在工作完成或无法完成时告诉 Controller，并允许使用状态消息和完成百分比值（0 到 100 之间的 Integer）更新 Controller。

最后我们定义了 Controller 对象。该对象中包含一些可以被 UI 代码调用的方法。其中包括 Start 方法，该方法可以通过为 Controller 对象提供对 Worker 对象的引用来启动后台操作。还包括 Cancel 方法，该方法用于请求取消操作。UI 也可以检查 Running 属性，查看是否存在取消请求；还可以检查 Percent 属性，查看任务完成的百分比。

Controller 类中包含的 constructor 方法接受 IClient 作为参数，还允许 UI 为 Controller 提供对窗体（用于处理 Worker 中的显示消息）的引用。

为了实现一系列动画点来显示线程的活动，我们将创建一个简单 Windows 窗体控件，该控件使用计时器以更改一系列 PictureBox 控件中的颜色。

keaide

实现方案
我们将在 Class Library（类库）项目中实现此架构，使其可用于需要运行后台进程的应用程序。

打开 Visual Studio .NET，然后创建一个名为 Background 的新 Class Library（类库）应用程序。由于此库将包含 Windows 窗体控件和窗体，因此需要使用 Add References（添加引用）对话框引用 System.Windows.Forms.dll 和 System.Windows.Drawing.dll。此外，我们可以使用项目的属性对话框在这些项目范围内导入命名空间，如图 6 所示。

keaide

此操作完成后，就可以开始编码了。让我们先从创建接口开始。

定义接口
在名为 IClient 的项目中添加一个类，并用以下代码替换其代码：

Public Interface IClient
  Sub Start(ByVal Controller As Controller)
  Sub Display(ByVal Text As String)
  Sub Failed(ByVal e As Exception)
  Sub Completed(ByVal Cancelled As Boolean)
End Interface

然后添加名为 IWorker 的类，并用以下代码替换其代码：

Public Interface IWorker
  Sub Initialize(ByVal Controller As IController)
  Sub Start()
End Interface

最后添加名为 IController 的类，代码如下：

Public Interface IController
  ReadOnly Property Running() As Boolean
  Sub Display(ByVal Text As String)
  Sub SetPercent(ByVal Percent As Integer)
  Sub Failed(ByVal e As Exception)
  Sub Completed(ByVal Cancelled As Boolean)
End Interface

至此，我们已定义了本文前面所述的所有类图表中的接口。现在可以实现 Controller 类了。

keaide

Controller 类
现在，我们可以实现架构的核心，Controller 类。此类中包含的代码可用于启动辅助线程，以及在辅助线程完成之前充当 UI 线程和辅助线程之间的媒介。

在名为 Controller 的项目中添加一个新类。首先添加 Imports，并声明一些变量：

Imports System.Threading

Public Class Controller
  Implements IController

  Private mWorker As IWorker
  Private mClient As Form
  Private mRunning As Boolean
  Private mPercent As Integer
然后需要声明一些委托。委托是方法的正式指针，而且方法的委托必须具有与方法本身相同的方法签名（参数类型等）。

委托的用途很广。在我们的示例中，委托非常重要，因为委托使我们可以让一个线程调用窗体上的方法，使其在该窗体的 UI 线程上运行。正如 IClient 所定义的那样，要在窗体上调用的三个方法都需要委托：

  ' 此委托签名与 IClient.Completed
  ' 中的签名相匹配，并用于安全地
  ' 调用 UI 线程上的方法
  Private Delegate Sub CompletedDelegate(ByVal Cancelled As Boolean)

  ' 此委托签名与 IClient.Display
  ' 中的签名相匹配，并用于安全地
  ' 调用 UI 线程上的方法
  Private Delegate Sub DisplayDelegate(ByVal Text As String)

  ' 此委托签名与 IClient.Failed
  ' 中的签名相匹配，并用于安全地
  ' 调用 UI 线程上的方法
  Private Delegate Sub FailedDelegate(ByVal e As Exception)

keaide

IClient 还定义了 Start 方法，但是该方法可以从 UI 线程调用，因此不需要委托。

下面编写将从 UI 线程调用的代码。代码中包括 constructor 方法、Start 和 Cancel 方法以及 Percent 属性。我将这些内容放入 Region 中，便于大家清楚地了解它们是从 UI 线程调用的。

#Region " 从 UI 线程调用的代码 "

  ' 使用客户端初始化 Controller
  Public Sub New(ByVal Client As IClient)
    mClient = CType(Client, Form)
  End Sub

  ' 此方法由 UI 调用，因此在
  ' UI 线程上运行。此处我们将
  ' 启动辅助线程
  Public Sub Start(Optional ByVal Worker As IWorker = Nothing)
    ' 如果辅助线程已经启动，将产生错误
    If mRunning Then
      Throw New Exception("Background process already running"
    End If

    mRunning = True

    ' 存储对辅助对象的引用，并
    ' 初始化辅助对象，使其包含
    ' 对 Controller 的引用
    mWorker = Worker
    mWorker.Initialize(Me)

    ' 创建后台线程
    ' 以进行后台操作
    Dim backThread As New Thread(AddressOf mWorker.Start)

    ' 开始后台工作
    backThread.Start()

    ' 告诉客户端后台工作已开始
    CType(mClient, IClient).Start(Me)
  End Sub

  ' 此代码由 UI 调用，因此在 UI
  ' 线程上运行。它只设置了请求
  ' 取消的标志
  Public Sub Cancel()
    mRunning = False
  End Sub

  ' 返回完成百分比值，并且
  ' 只被 UI 线程调用
  Public ReadOnly Property Percent() As Integer
    Get
      Return mPercent
    End Get
  End Property

#End Region

此处唯一比较特殊的代码位于 Start 方法中，我们可以在该方法中创建辅助线程然后启动该线程：

    Dim backThread As New Thread(AddressOf mWorker.Start)

    backThread.Start()

keaide

要创建线程，需要在 Worker 对象的 IWorker 接口上传递 Start 方法的地址。然后，只需调用线程对象的 Start 方法即可开始操作。此时我们要特别注意，UI 不应直接与 Worker 交互，Worker 也不应直接与 UI 交互。

请注意，Cancel 方法只设置一个标志，表明我们不希望继续运行。辅助代码应定期查看此标志，以确定是否应该停止运行。

现在，我们可以实现 Worker 对象运行时将由辅助线程调用的代码。此代码比较有趣，因为它必须将 Display 和 Completed 从辅助线程中转至 UI 线程，同时还要在 UI 线程上完成此操作。

要完成此操作，我们可以使用 Form 对象的 Invoke 方法。此方法接受窗体应该调用的方法的委托指针，以及包含该方法的参数的 Object 类型数组。

Invoke 方法不直接调用窗体上的方法，而是请求窗体返回并使用窗体的 UI 线程调用该方法。此操作可通过向窗体发送 Windows 消息在后台完成。这说明窗体获得这些方法调用的方式与从操作系统中获得 click 或 keypress 事件的方式基本相同。

通常，这些细节不会影响大局。结果由 Invoke 方法触发一个进程，通过该进程窗体将终止其 UI 线程上运行的方法，这就是我们要实现的目标。

再次重申，此代码位于 Region 内，目的是为了明确它将在辅助线程上调用：

#Region " 从辅助线程调用的代码 "

  ' 从辅助线程调用，以更新显示
  ' 这将触发对包含状态文本的 UI 的
  ' 方法调用 - 该调用是在 UI 线程上
  ' 进行的
  Private Sub Display(ByVal Text As String) _
      Implements IController.Display

    Dim disp As New DisplayDelegate( _
      AddressOf CType(mClient, IClient).Display)
    Dim ar() As Object = {Text}

    ' 调用 UI 线程上的客户端窗体
    ' 以更新显示
    mClient.BeginInvoke(disp, ar)

  End Sub