这是我的代码：
TYPE byq_type IS RECORD
( I2 NUMBER,
Ts NUMBER);
TYPE byq_type_array IS TABLE OF
byq_type INDEX BY BINARY_INTEGER;

我建立的byq_type_array 中假如有下面数据：
I2 Ts
-----------------
I1,10
I2,5
I3,20
I4,15

如何将上面的数据变成可以按Ts排序呢？
I2,5
I1,10
I4,15
I3,20



谢谢。

大家帮帮忙啊，我一直在线等。。。。。。。。。。。

我也想知道！！！！！

我现在只能是建立个临时表，把数据insert 到里面了，再select order by ts，有没有高手有别的好方法啊！

自己写个排序算法吧,在数据写入record时,就先排好队...

没用过，帮顶了，

I2是number型的，怎么会有字母呢？

贴子好老

方法一:
CREATE OR REPLACE TYPE TYP_ARR AS TABLE OF VARCHAR2(10);
/

DECLARE
   OBJ_ARR        TYP_ARR := TYP_ARR('B','A','F','D');
BEGIN

   DBMS_OUTPUT.PUT_LINE('======Before Sort====' );
   FOR I IN OBJ_ARR.FIRST..OBJ_ARR.LAST
   LOOP
      DBMS_OUTPUT.PUT_LINE(OBJ_ARR(I));
   END LOOP;

   SELECT CAST(MULTISET(SELECT * FROM TABLE(OBJ_ARR) ORDER BY 1) AS TYP_ARR)
   INTO   OBJ_ARR
   FROM   DUAL;

   DBMS_OUTPUT.PUT_LINE('======After Sort====' );
   FOR I IN OBJ_ARR.FIRST..OBJ_ARR.LAST
   LOOP
      DBMS_OUTPUT.PUT_LINE(OBJ_ARR(I));
   END LOOP;
END;
/

方法二:
DECLARE
   TYPE byq_type IS RECORD( I2 INT,
                           Ts VARCHAR2(5));
   TYPE byq_type_array IS TABLE OF byq_type;
   abc1  byq_type_array := byq_type_array();
   abc3  byq_type;
BEGIN
   abc1.extend(4);

   abc3.i2 := 3;
   abc3.Ts := 'B';
   abc1(1) := abc3;

   abc3.i2 := 9;
   abc3.Ts := 'A';
   abc1(2) := abc3;

   abc3.i2 := 6;
   abc3.Ts := 'D';
   abc1(3) := abc3;

   abc3.i2 := 5;
   abc3.Ts := 'E';
   abc1(4) := abc3;

   DBMS_OUTPUT.PUT_LINE('======Before Sort====' );
   FOR I IN abc1.FIRST..abc1.LAST LOOP
      DBMS_OUTPUT.PUT_LINE(abc1(I).I2 || '=====' || abc1(I).Ts);
   END LOOP;

   DECLARE
      TYPE byq_type_array IS TABLE OF byq_type INDEX BY BINARY_INTEGER;
      abc2 byq_type_array;
      idx  INTEGER;
   BEGIN
      idx := abc1.FIRST;
      LOOP
         abc2(abc1(idx).i2) := abc1(idx);
         idx := abc1.NEXT(idx);
         EXIT WHEN idx IS NULL;
      END LOOP;

      abc1.DELETE;

      idx := abc2.FIRST;
      LOOP
         abc1.EXTEND;
         abc1(abc1.LAST) := abc2(idx);
         idx := abc2.NEXT(idx);
         EXIT WHEN idx IS NULL;
      END LOOP;
   END;

   DBMS_OUTPUT.PUT_LINE('======After Sort====' );
   FOR I IN abc1.FIRST..abc1.LAST LOOP
      DBMS_OUTPUT.PUT_LINE(abc1(I).I2 || '=====' || abc1(I).Ts);
   END LOOP;
END;
/