如何在存储过程中变量传递表名，在cursor中调用？
我的脚本如下：
CREATE OR REPLACE PROCEDURE Dfsc_Yhqfxx (dwbm IN VARCHAR2, ny IN VARCHAR2)
AS
table_name_yhda varchar(18);
CURSOR S_YS(table_name varchar2,P_HH VARCHAR2,P_YDNY VARCHAR2) IS SELECT YSDF FROM table_name WHERE YDNY=P_YDNY AND HH=P_HH;

begin
--拼凑要处理的表名
table_name_yhda:='DFSC.DFCD_YHDA'||'_'||'15'||'_'||'2004';
OPEN S_YS(table_name_yhdf,'100000338','200405'); --取当前用户应收
IF S_YS%FOUND THEN
FETCH S_YS INTO v_row.ys;
ELSE
V_row.ys:=0;
DBMS_OUTPUT.PUT_LINE(v_row.YHH||'应收无法取得');
END IF;
CLOSE S_YS;
end;

始终没有人能回答，郁闷

还是没有人回答

你把sql当动态sql处理就可以了

dbms_sql 包一定能满足你的要求

谁能提供例子参照，谢谢

google 能提供

PROCEDURE print_table (tab_name VARCHAR2) IS
TYPE RefCurTyp IS REF CURSOR;
cv RefCurTyp;
p Person;
h Hobbies;
BEGIN
OPEN cv FOR ’SELECT pers, hobbs FROM ’ || tab_name;
LOOP
FETCH cv INTO p, h;
EXIT WHEN cv%NOTFOUND;
-- print attributes of ’p’ and elements of ’h’
END LOOP;
CLOSE cv;
END;

谢谢taol提供的例子

to:biti_rainy
如果goolge能提供我也不会耽误大家时间在这里发贴了

在发贴之前我就搜索过了

http://download-west.oracle.com/ ... 12/d_sql.htm#998168

如果仅仅是表名的变化，或者字段个数不变，上面有人已经说了，不过dbms_sql提供了强大的功能，但使用起来复杂一些


Example 2
The following sample procedure is passed the names of a source and a destination table, and copies the rows from the source table to the destination table. This sample procedure assumes that both the source and destination tables have the following columns:

id        of type NUMBER
name      of type VARCHAR2(30)
birthdate of type DATE


This procedure does not specifically require the use of dynamic SQL; however, it illustrates the concepts of this package.

CREATE OR REPLACE PROCEDURE copy (
     source      IN VARCHAR2,
     destination IN VARCHAR2) IS
     id_var             NUMBER;
     name_var           VARCHAR2(30);
     birthdate_var      DATE;
     source_cursor      INTEGER;
     destination_cursor INTEGER;
     ignore             INTEGER;
  BEGIN

  -- Prepare a cursor to select from the source table:
     source_cursor := dbms_sql.open_cursor;
     DBMS_SQL.PARSE(source_cursor,
         'SELECT id, name, birthdate FROM ' || source,
          DBMS_SQL.native);
     DBMS_SQL.DEFINE_COLUMN(source_cursor, 1, id_var);
     DBMS_SQL.DEFINE_COLUMN(source_cursor, 2, name_var, 30);
     DBMS_SQL.DEFINE_COLUMN(source_cursor, 3, birthdate_var);
     ignore := DBMS_SQL.EXECUTE(source_cursor);

  -- Prepare a cursor to insert into the destination table:
     destination_cursor := DBMS_SQL.OPEN_CURSOR;
     DBMS_SQL.PARSE(destination_cursor,
                  'INSERT INTO ' || destination ||
                  ' VALUES (:id_bind, :name_bind, :birthdate_bind)',
                   DBMS_SQL.native);

  -- Fetch a row from the source table and insert it into the destination table:
     LOOP
       IF DBMS_SQL.FETCH_ROWS(source_cursor)>0 THEN
         -- get column values of the row
         DBMS_SQL.COLUMN_VALUE(source_cursor, 1, id_var);
         DBMS_SQL.COLUMN_VALUE(source_cursor, 2, name_var);
         DBMS_SQL.COLUMN_VALUE(source_cursor, 3, birthdate_var);

  -- Bind the row into the cursor that inserts into the destination table. You
  -- could alter this example to require the use of dynamic SQL by inserting an
  -- if condition before the bind.
        DBMS_SQL.BIND_VARIABLE(destination_cursor, ':id_bind', id_var);
        DBMS_SQL.BIND_VARIABLE(destination_cursor, ':name_bind', name_var);
        DBMS_SQL.BIND_VARIABLE(destination_cursor, ':birthdate_bind',
birthdate_var);
        ignore := DBMS_SQL.EXECUTE(destination_cursor);
      ELSE

  -- No more rows to copy:
        EXIT;
      END IF;
    END LOOP;

  -- Commit and close all cursors:
     COMMIT;
     DBMS_SQL.CLOSE_CURSOR(source_cursor);
     DBMS_SQL.CLOSE_CURSOR(destination_cursor);
   EXCEPTION
     WHEN OTHERS THEN
       IF DBMS_SQL.IS_OPEN(source_cursor) THEN
         DBMS_SQL.CLOSE_CURSOR(source_cursor);
       END IF;
       IF DBMS_SQL.IS_OPEN(destination_cursor) THEN
         DBMS_SQL.CLOSE_CURSOR(destination_cursor);
       END IF;
       RAISE;
  END;
/

非常感谢biti_rainy的精彩回答，我得到两种解决方法