查看: 3454|回复: 3

[每日一题] PL/SQL Challenge 每日一题:2018-3-7 CONTINUE语句

[复制链接]
论坛徽章:
530
奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:532009日食纪念
日期:2009-07-22 09:30:00
发表于 2018-3-10 05:29 | 显示全部楼层 |阅读模式

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

哪些选项在执行之后会显示如下文本?

Natural
Natural
Uh Oh

(A)
DECLARE
   TYPE strings_t IS TABLE OF VARCHAR2 (100);

   l_strings   strings_t := strings_t (1, 2, 'a2c');
BEGIN
   FOR indx IN 1 .. l_strings.COUNT
   LOOP
      IF l_strings (indx) > 0
      THEN
         DBMS_OUTPUT.put_line ('Natural');
         CONTINUE;
      ELSE
         DBMS_OUTPUT.put_line ('Unnatural');
      END IF;

      IF INSTR (l_strings (indx), '2') > 0
      THEN
         DBMS_OUTPUT.put_line ('Positive');
         CONTINUE;
      ELSE
         DBMS_OUTPUT.put_line ('Uncertain');
      END IF;
   END LOOP;
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line ('Uh Oh');
END;
/

(B)
DECLARE
   TYPE strings_t IS TABLE OF VARCHAR2 (100);

   l_strings   strings_t := strings_t (1, 2, 'a2c');
BEGIN
   FOR indx IN 1 .. l_strings.COUNT
   LOOP
      IF l_strings (indx) > 0
      THEN
         DBMS_OUTPUT.put_line ('Natural');
      ELSE
         DBMS_OUTPUT.put_line ('Unnatural');
      END IF;

      IF INSTR (l_strings (indx), '2') > 0
      THEN
         DBMS_OUTPUT.put_line ('Positive');
      ELSE
         DBMS_OUTPUT.put_line ('Uncertain');
      END IF;
   END LOOP;
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line ('Uh Oh');
END;
/

(C)
DECLARE
   TYPE strings_t IS TABLE OF VARCHAR2 (100);

   l_strings   strings_t := strings_t (1, 2, 'a2c');
BEGIN
   FOR indx IN 1 .. l_strings.COUNT
   LOOP
      IF l_strings (indx) > 0
      THEN
         DBMS_OUTPUT.put_line ('Natural');
      ELSE
         DBMS_OUTPUT.put_line ('Unnatural');
      END IF;
      
      CONTINUE WHEN l_strings (indx) > 0;

      IF INSTR (l_strings (indx), '2') > 0
      THEN
         DBMS_OUTPUT.put_line ('Positive');
      ELSE
         DBMS_OUTPUT.put_line ('Uncertain');
      END IF;
      
      CONTINUE WHEN INSTR (l_strings (indx), '2') > 0;
   END LOOP;
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line ('Uh Oh');
END;
/

(D)
DECLARE
   TYPE strings_t IS TABLE OF VARCHAR2 (100);

   l_strings   strings_t := strings_t (1, 2, 'a2c');
BEGIN
   FOR indx IN 1 .. l_strings.COUNT
   LOOP
      IF l_strings (indx) > 0
      THEN
         DBMS_OUTPUT.put_line ('Natural');
         GOTO all_done;
      ELSE
         DBMS_OUTPUT.put_line ('Unnatural');
      END IF;

      IF INSTR (l_strings (indx), '2') > 0
      THEN
         DBMS_OUTPUT.put_line ('Positive');
         GOTO all_done;
      ELSE
         DBMS_OUTPUT.put_line ('Uncertain');
      END IF;
      
      <<all_done>>
      NULL;
   END LOOP;
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line ('Uh Oh');
END;
/
认证徽章
论坛徽章:
49
秀才
日期:2018-12-05 13:58:28秀才
日期:2018-11-13 14:57:47秀才
日期:2018-11-13 14:57:26秀才
日期:2018-08-31 10:54:12秀才
日期:2018-08-31 10:53:55技术图书徽章
日期:2018-08-31 10:48:56秀才
日期:2018-08-31 10:48:48秀才
日期:2018-08-31 10:48:48秀才
日期:2018-08-31 10:48:48秀才
日期:2018-08-31 10:48:34
发表于 2018-3-12 09:13 | 显示全部楼层
ACD
CONTINUE:继续执行循环不在执行后面的语句11g新功能,和break(Oracle里面是exit)不一样,break(exit)直接跳出.
A,正确的使用CONTINUE,我们通常的写法,
B,不行,没有使用任何终止本次循环的语句,第二个if条件仍然会执行
C:正确,CONTINUE when XXXX ;这种写法没见过,学习了。
D:正确,11G 之前实现continue的另外写法不。我是这么感觉的。

使用道具 举报

回复
论坛徽章:
530
奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:532009日食纪念
日期:2009-07-22 09:30:00
 楼主| 发表于 2018-3-13 03:44 | 显示全部楼层
答案ACD, 2楼得奖。

A:(推荐)
我用了CONTINUE语句,当第一个IF子句取值为TRUE的时候就避免执行第二个IF语句
B:
这个选项会导致下列文本被显示:

Natural
Uncertain
Natural
Positive
Uh Oh

因为没有“捷径”逻辑(CONTINUE 或者 GOTO),两个IF子句每次都会被执行。

C:(不推荐)
这个正如选项A,但是我用了CONTINUE WHEN。这个方法是没问题的,但前提是你没有重复条件表达式,此处我们在IF语句中看到了,然后又在WHEN子句中重复了。在这种情况下,请将CONTINUE放入IF子句。

D:(不推荐)
是的,它是“正确”的,但请不要用GOTO,除非是万不得已,而此处你并不需要。用CONTINUE就行了!

使用道具 举报

回复
认证徽章
论坛徽章:
216
布鲁克
日期:2016-05-31 16:31:17弗兰奇
日期:2016-05-31 16:31:17妮可·罗宾
日期:2016-07-04 11:53:09托尼托尼·乔巴
日期:2016-05-31 16:31:17山治
日期:2016-05-31 16:31:17乌索普
日期:2016-05-31 16:31:17娜美
日期:2016-05-31 16:31:17罗罗诺亚·索隆
日期:2016-05-31 16:31:17蒙奇·D·路飞
日期:2016-05-31 16:31:17乌索普
日期:2016-08-03 10:26:32
发表于 2018-5-22 15:15 | 显示全部楼层
截止到今日每日一题奖励已发,辛苦newkid大师
本期从2-16到3-7期
每10期题目发一次奖,10期内获奖最多的再奖励一本技术图书~原有的秀才系列徽章继续根据兑换规则兑换礼品~
大家多多努力哦~
本期获奖情况如下(3-2无人获奖)
wmxcn2000
a875458744
solomon_007
lastwinner
lastwinner
a875458744
sse_zero
visual2006
sse_zero
恭喜sse_zero、lastwinner、a875458744 同学获得一本技术图书,图书徽章已发,可以到书单换任意一本~
各位其他童鞋继续加油哦~

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则 发表回复

TOP技术积分榜 社区积分榜 徽章 团队 统计 知识索引树 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛
CopyRight 1999-2011 itpub.net All Right Reserved. 北京盛拓优讯信息技术有限公司版权所有 联系我们 
京ICP备09055130号-4  北京市公安局海淀分局网监中心备案编号:11010802021510 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表