ITPUB论坛-中国最专业的IT技术社区

 找回密码
 注册
查看: 699|回复: 3

[每日一题] PL/SQL Challenge 每日一题:2017-12-27 NULL的比较

[复制链接]
论坛徽章:
486
秀才
日期:2015-09-09 10:33:01秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12状元
日期:2015-11-23 10:04:09举人
日期:2015-11-23 10:04:09秀才
日期:2016-01-06 14:10:21秀才
日期:2016-01-06 14:10:21秀才
日期:2016-01-06 14:10:21秀才
日期:2016-01-06 14:10:21
发表于 2018-1-2 05:45 | 显示全部楼层 |阅读模式
最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我执行了这个语句:

CREATE OR REPLACE PROCEDURE qz_show_boolean (str IN VARCHAR2, val IN BOOLEAN)
IS
BEGIN
   DBMS_OUTPUT.put_line (
      str || ' - ' ||
      CASE val WHEN TRUE THEN 'TRUE'
               WHEN FALSE THEN 'FALSE'
               ELSE 'NULL' END);
END qz_show_boolean;
/

哪些选项创建了一个名为QZ_IS_EQUAL的函数,使得下列代码块执行之后,会显示这个文本:

1 = NULL - FALSE
NULL = 1 - FALSE
1 = 1 - TRUE
1 = 2 - FALSE
NULL = NULL - TRUE

BEGIN
   qz_show_boolean ('1 = NULL', qz_is_equal (1, NULL));
   qz_show_boolean ('NULL = 1', qz_is_equal (NULL, 1));
   qz_show_boolean ('1 = 1', qz_is_equal (1, 1));
   qz_show_boolean ('1 = 2', qz_is_equal (1, 2));
   qz_show_boolean ('NULL = NULL', qz_is_equal (NULL, NULL));
END;
/

(A)
CREATE OR REPLACE FUNCTION qz_is_equal (val1 IN INTEGER, val2 IN INTEGER)
   RETURN BOOLEAN
IS
BEGIN
   RETURN val1 = val2;
END;
/

(B)
CREATE OR REPLACE FUNCTION qz_is_equal (val1 IN INTEGER, val2 IN INTEGER)
   RETURN BOOLEAN
IS
   c_never_used   CONSTANT VARCHAR2 (1) := CHR (7);
BEGIN
   RETURN NVL (val1, c_never_used) = NVL (val2, c_never_used);
END;
/

(C)
CREATE OR REPLACE FUNCTION qz_is_equal (val1 IN INTEGER, val2 IN INTEGER)
   RETURN BOOLEAN
IS
BEGIN
   RETURN val1 = val2 OR (val1 IS NULL AND val2 IS NULL);
END;
/

(D)
CREATE OR REPLACE FUNCTION qz_is_equal (val1 IN INTEGER, val2 IN INTEGER)
   RETURN BOOLEAN
IS
BEGIN
   RETURN NVL (val1 = val2, FALSE) OR (val1 IS NULL AND val2 IS NULL);
END;
/

(E)
CREATE OR REPLACE FUNCTION qz_is_equal (val1 IN INTEGER, val2 IN INTEGER)
   RETURN BOOLEAN
IS
   l_compare   INTEGER;
BEGIN
   SELECT DECODE (val1, val2, 1, 0) INTO l_compare FROM DUAL;

   RETURN l_compare = 1;
END;
/

(F)
CREATE OR REPLACE FUNCTION qz_is_equal (val1 IN INTEGER, val2 IN INTEGER)
   RETURN BOOLEAN
IS
BEGIN
   RETURN    (val1 IS NOT NULL AND val2 IS NOT NULL AND val1 = val2)
          OR (val1 IS NULL AND val2 IS NULL);
END;
/

论坛徽章:
20
2012新春纪念徽章
日期:2012-01-04 11:58:44秀才
日期:2016-03-01 09:55:08秀才
日期:2016-03-01 09:55:08秀才
日期:2016-03-28 10:21:13秀才
日期:2016-03-28 10:30:00秀才
日期:2016-03-28 10:30:00秀才
日期:2016-03-28 10:30:00秀才
日期:2016-04-29 15:04:10秀才
日期:2016-04-29 15:10:43秀才
日期:2016-03-01 09:55:08
发表于 2018-1-2 09:20 | 显示全部楼层
正确答案:DEF  
A:null跟任何相比结果都为null;
B:会报错,字符型无法转化为数字型;
C:null跟任何相比结果都为null;

使用道具 举报

回复
论坛徽章:
20
2012新春纪念徽章
日期:2012-01-04 11:58:44秀才
日期:2016-03-01 09:55:08秀才
日期:2016-03-01 09:55:08秀才
日期:2016-03-28 10:21:13秀才
日期:2016-03-28 10:30:00秀才
日期:2016-03-28 10:30:00秀才
日期:2016-03-28 10:30:00秀才
日期:2016-04-29 15:04:10秀才
日期:2016-04-29 15:10:43秀才
日期:2016-03-01 09:55:08
发表于 2018-1-2 09:27 | 显示全部楼层
E选项的Decode会判定两个null相等,输出为1。

使用道具 举报

回复
论坛徽章:
486
秀才
日期:2015-09-09 10:33:01秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12状元
日期:2015-11-23 10:04:09举人
日期:2015-11-23 10:04:09秀才
日期:2016-01-06 14:10:21秀才
日期:2016-01-06 14:10:21秀才
日期:2016-01-06 14:10:21秀才
日期:2016-01-06 14:10:21
 楼主| 发表于 2018-1-3 05:00 | 显示全部楼层
答案DEF, 2楼得奖。

A:
NULL 永远也不会等于(或者不等于)NULL。
这种简单的公式不能得到我们想要的结果。
B: 这个选项在执行时会报错:

ORA-06502: PL/SQL: numeric or value error:
                   character to number conversion error
问题在于NVL需要两个值是同样的类型——这是很合理的。但是你无法将CHR(7)转换成一个整数!

C: 这个选项会导致下列的文本被显示:

1 = NULL - NULL
NULL = 1 - NULL
1 = 1 - TRUE
1 = 2 - FALSE
NULL = NULL - TRUE

这是因为我们简单地用了 "val1 = val2" 来处理其中有一个值为NULL,而另一个不为NULL的情况。

D:
我用了NVL作为"val1 = val2"的任何结果的“万能处理器”,所以如果只有一个值为NULL, NVL将NULL转换为FALSE。
同时,“两个都为NULL”的情况被后半部的OR处理掉了,所以我们能看到所需的结果。

E:(不推荐)
DECODE将两个NULL认为相等。有趣的函数!

所以你可以在DUAL上执行一个SELECT来调用DECODE。但是我建议你别这么做。不要为你的处理再加上一个上下文切换到SQL的开销,除非迫不得已。

F:(推荐)
在这个版本中,要么两个都为NULL, 要么两个都不为NULL而且相等。

这也会产生所需的输出。

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则

DTCC2018购票6.8折优惠进行时

中国数据库技术大会是国内数据库及大数据领域规模最大、最受欢迎的技术交流盛会。 2018年5月10-12日,第九届中国数据库技术大会将如约而至。本届大会以“数领先机•智赢未来”为主题,设定2大主会场及20个技术专场,邀请来自国内外互联网、金融、教育等行业百余位技术专家,共同探讨Oracle、MySQL、NoSQL、大数据等领域的前瞻性热点话题与技术。
----------------------------------------
优惠时间:2018年2月13日前

报名链接>>
TOP技术积分榜 社区积分榜 徽章 电子杂志 团队 统计 虎吧 老博客 知识索引树 读书频道 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档 | IT博客
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛 | SAP ERP系统
CopyRight 1999-2011 itpub.net All Right Reserved. 北京盛拓优讯信息技术有限公司版权所有 联系我们 网站律师 隐私政策 知识产权声明
京ICP备16024965号 北京市公安局海淀分局网监中心备案编号:11010802021510 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表