ITPUB论坛-中国最专业的IT技术社区

 找回密码
 注册
查看: 1147|回复: 2

[每日一题] PL/SQL Challenge 每日一题:2017-11-20 过程重载的限制

[复制链接]
论坛徽章:
480
榜眼
日期:2015-09-09 10:34:21秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12状元
日期:2015-11-23 10:04:09举人
日期:2015-11-23 10:04:09
发表于 2017-11-23 06:05 | 显示全部楼层 |阅读模式
(原发表于 2011-8-29)

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我创建了这张表及其数据:

CREATE TABLE plch_employees
(
   employee_id     INTEGER
, last_name       VARCHAR2 (100)
, salary          NUMBER
, department_id   INTEGER
)
/

BEGIN
   INSERT INTO plch_employees
        VALUES (100
              , 'Jobs'
              , 1000000
              , 100);

   INSERT INTO plch_employees
        VALUES (200
              , 'Ellison'
              , 1000000
              , 200);

   INSERT INTO plch_employees
        VALUES (300
              , 'Gates'
              , 1000000
              , 200);

   COMMIT;
END;
/

然后我创建了这个包:

CREATE OR REPLACE PACKAGE plch_pkg
IS
   SUBTYPE currency_t IS NUMBER (10, 2);

   SUBTYPE currency_desc_t IS VARCHAR2 (100);

   FUNCTION total_salary (department_id_in IN INTEGER)
      RETURN currency_t;

   FUNCTION total_salary (department_id_in IN INTEGER)
      RETURN currency_desc_t;
END;
/

CREATE OR REPLACE PACKAGE BODY plch_pkg
IS
   FUNCTION total_salary (department_id_in IN INTEGER)
      RETURN currency_t
   IS
      l_total   currency_t;
   BEGIN
      SELECT SUM (salary)
        INTO l_total
        FROM plch_employees e
       WHERE e.department_id = total_salary.department_id_in;

      RETURN l_total;
   END;

   FUNCTION total_salary (department_id_in IN INTEGER)
      RETURN currency_desc_t
   IS
      l_total   currency_t;
   BEGIN
      SELECT SUM (salary)
        INTO l_total
        FROM plch_employees e
       WHERE e.department_id = total_salary.department_id_in;

      RETURN TO_CHAR (l_total, 'FML999G999G999');
   END;
END;
/

哪些选项包含了一个代码块,在执行之后会显示 "$2,000,000" ?

(A)
DECLARE
   l_total_salary        plch_pkg.currency_t;
   l_total_salary_desc   plch_pkg.currency_desc_t;
BEGIN
   l_total_salary := plch_pkg.total_salary (200);
   l_total_salary_desc := plch_pkg.total_salary (200);
   DBMS_OUTPUT.put_line (l_total_salary_desc);
END;
/

(B)
DECLARE
   l_total_salary_desc   plch_pkg.currency_desc_t;
BEGIN
   l_total_salary_desc := plch_pkg.total_salary (200);
   DBMS_OUTPUT.put_line (l_total_salary_desc);
END;
/

(C)
BEGIN
   DBMS_OUTPUT.put_line (plch_pkg.total_salary (200));
END;
/

(D)
DECLARE
   l_total_salary        NUMBER;
   l_total_salary_desc   VARCHAR2 (100);
BEGIN
   l_total_salary := plch_pkg.total_salary (200);
   l_total_salary_desc := plch_pkg.total_salary (200);
   DBMS_OUTPUT.put_line (l_total_salary_desc);
END;
/


(E)
以上答案都不对。

论坛徽章:
18
秀才
日期:2016-04-29 15:11:10秀才
日期:2017-04-05 13:27:59秀才
日期:2017-04-05 13:23:10秀才
日期:2017-04-05 13:23:10秀才
日期:2017-04-05 13:23:10秀才
日期:2017-04-05 13:22:59秀才
日期:2017-03-02 10:35:32秀才
日期:2017-01-20 11:06:21秀才
日期:2017-01-20 11:00:36秀才
日期:2017-01-20 11:04:31
发表于 2017-11-23 16:04 | 显示全部楼层
我选E
函数重载名称和参数个数、类型不能完全一致。

使用道具 举报

回复
论坛徽章:
480
榜眼
日期:2015-09-09 10:34:21秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12秀才
日期:2015-11-23 10:03:12状元
日期:2015-11-23 10:04:09举人
日期:2015-11-23 10:04:09
 楼主| 发表于 2017-11-24 04:37 | 显示全部楼层
答案E, 2楼得奖。

所有选项执行时都会报这个错:
PLS-00307: too many declarations of 'TOTAL_SALARY' match this call

Oracle 不允许你调用下列情形的重载子程序:
定义在schema级别(不是在包里)的程序单元;
形式参数仅仅在mode上有区别;
形式参数仅仅在subtype上有区别;
仅仅在返回值的数据类型上有区别的函数,即使数据类型属于不同类别。

即使我将子类型声明为特定的数据类型,即使我调用了函数并且将其返回值赋予NUMBER或者VARCHAR2变量,即使我用了“硬编码”书写的基础数据类型来声明变量,ORACLE还是会报错:
"PLS-00307: too many declarations of 'TOTAL_SALARY' match this call"

所以,如果你在编译代码时得到这个错误,检查一下这个程序名的重载声明清空,如果是函数,要确保除了RETURN的数据类型之外,还有其他区别。

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则

TOP技术积分榜 社区积分榜 徽章 电子杂志 团队 统计 虎吧 老博客 知识索引树 读书频道 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档 | IT博客
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛 | SAP ERP系统
CopyRight 1999-2011 itpub.net All Right Reserved. 北京盛拓优讯信息技术有限公司版权所有 联系我们 网站律师 隐私政策 知识产权声明
京ICP备16024965号 北京市公安局海淀分局网监中心备案编号:11010802021510 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表