PL/SQL Challenge 每日一题：2017-6-6 布尔型表达式

newkid

(原发表于 2011-7-7)

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正)，其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引：
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处：
http://www.plsqlchallenge.com/

作者：Steven Feuerstein

运行环境：SQLPLUS, SERVEROUTPUT已打开
注：本题给出答案时候要求给予简要说明才能得到奖品

哪些选项实现了plch_validity函数，使得下列代码块执行之后：
BEGIN
   DBMS_OUTPUT.put_line (plch_validity (TRUE));
   DBMS_OUTPUT.put_line (plch_validity (FALSE));
END;
/


这两行文本会被显示：

VALID
INVALID


(A)
CREATE OR REPLACE FUNCTION plch_validity (value_in IN BOOLEAN)
   RETURN VARCHAR2
IS
BEGIN
   RETURN CASE
             WHEN value_in IS TRUE THEN 'VALID'
             WHEN value_in IS FALSE THEN 'INVALID'
             ELSE 'NULL'
          END;
END;
/

(B)
CREATE OR REPLACE FUNCTION plch_validity (value_in IN BOOLEAN)
   RETURN VARCHAR2
IS
BEGIN
   RETURN CASE
             WHEN value_in = TRUE THEN 'VALID'
             WHEN value_in = FALSE THEN 'INVALID'
             ELSE 'NULL'
          END;
END;
/

(C)
CREATE OR REPLACE FUNCTION plch_validity (value_in IN BOOLEAN)
   RETURN VARCHAR2
IS
   l_return   VARCHAR2 (7);
BEGIN
   SELECT CASE
             WHEN value_in THEN 'VALID'
             WHEN NOT value_in THEN 'INVALID'
             ELSE 'NULL'
          END
     INTO l_return
     FROM sys.DUAL;
   RETURN l_return;
END;
/


(D)
CREATE OR REPLACE FUNCTION plch_validity (value_in IN BOOLEAN)
   RETURN VARCHAR2
IS
BEGIN
   RETURN CASE
             WHEN value_in THEN 'VALID'
             WHEN NOT value_in THEN 'INVALID'
             ELSE 'NULL'
          END;
END;
/

wmxcn2000

A、在逻辑运算中 IS （NOT）后，只能跟 NULL，不能写其他的表达式或值；
B、这里的 TRUE 和 FALSE 就相当于一个常量，如同 colA =100 一样；
C、BOOLEAN 不能出现在 SELECT .. INTO 中，这个是非 PLSQL  语法（不知道这样描述，是不是很不专业）；
D、RETURN 相当于 SQL ，而不是 PLSQL；

这样一样，B、D 是对的；

wd10093588

答案B、D。但2L wmxcn2000 解释的不对。
A、布尔类型的表达式比较运算符不能用is。并不是他所说的is后面只能跟NULL，比如is any， is empty。而且is（not）null根本就不是逻辑运算，属于非比较条件表达式，Oracle官方在线文档将其归类到condition下的null condition类别里了；
B、布尔类型的确可理解为常量，这里true等价于某个二进制值。因此可以用等号比较数值型数据；
C、http://docs.oracle.com/cd/E11882 ... entals.htm#LNPLS218 官方解释：
Because SQL does not have a BOOLEAN type, variable_name cannot be a BOOLEAN variable. 并不是像他说的不是PL/SQL语法，这恰巧是PL/SQL语法，只是因为SQL中没有布尔类型而已；
D、RETURN本就是PL/SQL语法，而且create or replace fuction的语法中也要求必须要有返回值，RETURN子句或输出（返回）参数。此处是将变量值直接当做布尔表达式进行条件判断，返回结果值。

newkid

答案BD, 3楼得奖。

A: 一个布尔型参数或者表达式直接取值为TRUE或FALSE(或NULL)。你不需要显式地检测它是TRUE或FALSE。即使你这么做了，语法也不对。你可以将一个布尔值用等号和TRUE做比较，如"value_in = TRUE"，但你显然不需要这么做。参数本身就会得到这些值了。

B: 方法可行，但不是最佳的。你不需要将布尔参数（表达式）和TRUE或者FALSE做比较。它自己就会取到这些值！所以WHEN子句的"= TRUE" 和 "= FALSE"仅仅是“噪音”，会阻碍阅读代码。

C: 虽然你能在SQL语句中调用CASE，你不能引用布尔型的变量，因为这是一个PL/SQL特有的数据类型。

D: 这是最自然简单的方法。你不需要将布尔参数（表达式）和TRUE或者FALSE做比较。它自己就会取到这些值！

wmxcn2000

wd10093588 发表于 2017-6-12 18:13
答案B、D。但2L wmxcn2000 解释的不对。
A、布尔类型的表达式比较运算符不能用is。并不是他所说的is后面只 ...

学习了。

蒲公英IDC

路过。。。