查看: 6061|回复: 2

[每日一题] PL/SQL Challenge 每日一题:2017-4-24 带LOG ERROR的DML语句

[复制链接]
论坛徽章:
527
奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:532009日食纪念
日期:2009-07-22 09:30:00
发表于 2017-5-4 02:59 | 显示全部楼层 |阅读模式

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Tony Winn

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我执行了下列语句:

CREATE TABLE qz_data
(
  N  NUMBER(3),
  S  VARCHAR2(9),
  D  DATE
)
/

BEGIN
   INSERT INTO qz_data (n, s) VALUES (100, 'Junaid');
   INSERT INTO qz_data (n, s) VALUES (101, 'Gav');
   INSERT INTO qz_data (n, s) VALUES (102, 'Chris');
   INSERT INTO qz_data (n, s) VALUES (103, 'Seamus');
   INSERT INTO qz_data (n, s) VALUES (104, 'Tony');
   INSERT INTO qz_data (n, s) VALUES (105, 'Fiona');
   INSERT INTO qz_data (n, s) VALUES (106, 'Donovan');
   INSERT INTO qz_data (n, s) VALUES (107, 'Grant');
   INSERT INTO qz_data (n, s) VALUES (108, 'Stuart');
   INSERT INTO qz_data (n, s) VALUES (109, 'Andy');
   COMMIT;
END;
/

BEGIN
   DBMS_ERRLOG.create_error_log (dml_table_name => 'QZ_DATA');
END;
/

CREATE OR REPLACE PACKAGE qz_pkg AUTHID DEFINER
IS
   TYPE ids_t IS TABLE OF INTEGER;

  PROCEDURE Show_Results;

END;
/

CREATE OR REPLACE PACKAGE BODY qz_pkg
IS

  PROCEDURE Show_Results IS
    l_good NUMBER;
    l_bad  NUMBER;
  BEGIN
    SELECT count(*)
    INTO   l_good
    FROM   QZ_DATA
    WHERE  D IS NOT NULL
    ;

    SELECT count(*)
    INTO   l_bad
    FROM   ERR$_QZ_DATA
    ;

    DBMS_OUTPUT.Put_Line('Good = ' || l_good || ' ; Bad = ' || l_bad);
  END;

END;
/

哪些选项在执行之后会在屏幕上显示 "Good = 3 ; Bad = 7" (可能还有其它文本)?


(A)
BEGIN

   UPDATE qz_data
      SET s = s || s,
          d = SYSDATE
   LOG ERRORS REJECT LIMIT UNLIMITED
   ;

   qz_pkg.show_results;
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.Put_Line('Ugly!');
      qz_pkg.show_results;
END;
/

(B)
BEGIN

   UPDATE qz_data
      SET s = s || s,
          d = SYSDATE
   LOG ERRORS REJECT LIMIT 3
   ;

   qz_pkg.show_results;
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.Put_Line('Ugly!');
      qz_pkg.show_results;
END;
/

(C)
DECLARE
   l_lows    qz_pkg.ids_t := qz_pkg.ids_t (100, 103, 106, 109);
   l_highs   qz_pkg.ids_t := qz_pkg.ids_t (102, 105, 108, 109);
BEGIN
   FOR indx IN 1 .. l_lows.COUNT
   LOOP
      UPDATE qz_data
         SET s = s || s,
             d = SYSDATE
       WHERE n BETWEEN l_lows (indx) AND l_highs (indx)
       LOG ERRORS REJECT LIMIT 3
      ;
   END LOOP;

   qz_pkg.show_results;
EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.Put_Line('Ugly!');
    qz_pkg.show_results;
END;
/

(D)
DECLARE
   l_lows    qz_pkg.ids_t := qz_pkg.ids_t (100, 103, 106, 109);
   l_highs   qz_pkg.ids_t := qz_pkg.ids_t (102, 105, 108, 109);
BEGIN
   FORALL indx IN 1 .. l_lows.COUNT
      UPDATE qz_data
         SET s = s || s,
             d = SYSDATE
       WHERE n BETWEEN l_lows (indx) AND l_highs (indx)
       LOG ERRORS REJECT LIMIT UNLIMITED
      ;

   qz_pkg.show_results;
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.Put_Line('Ugly!');
      qz_pkg.show_results;
END;
/


(E)
DECLARE
   l_lows    qz_pkg.ids_t := qz_pkg.ids_t (100, 103, 106, 109);
   l_highs   qz_pkg.ids_t := qz_pkg.ids_t (102, 105, 108, 109);
BEGIN
   FORALL indx IN 1 .. l_lows.COUNT
      UPDATE qz_data
         SET s = s || s,
             d = SYSDATE
       WHERE n BETWEEN l_lows (indx) AND l_highs (indx)
       LOG ERRORS REJECT LIMIT 3
      ;

   qz_pkg.show_results;
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.Put_Line('Ugly!');
      qz_pkg.show_results;
END;
/

(F)
DECLARE
   l_lows    qz_pkg.ids_t := qz_pkg.ids_t (100, 105);
   l_highs   qz_pkg.ids_t := qz_pkg.ids_t (104, 109);
BEGIN
   FORALL indx IN 1 .. l_lows.COUNT
      UPDATE qz_data
         SET s = s || s,
             d = SYSDATE
       WHERE n BETWEEN l_lows (indx) AND l_highs (indx)
       LOG ERRORS REJECT LIMIT 3
      ;

   qz_pkg.show_results;
EXCEPTION
   WHEN OTHERS THEN
      DBMS_OUTPUT.Put_Line('Ugly!');
      qz_pkg.show_results;
END;
/
论坛徽章:
324
生肖徽章2007版:猴
日期:2008-05-16 11:28:59生肖徽章2007版:马
日期:2008-10-08 17:01:01SQL大赛参与纪念
日期:2011-04-13 12:08:17授权会员
日期:2011-06-17 16:14:53ITPUB元老
日期:2011-06-21 11:47:01ITPUB官方微博粉丝徽章
日期:2011-07-01 09:45:27ITPUB十周年纪念徽章
日期:2011-09-27 16:30:472012新春纪念徽章
日期:2012-01-04 11:51:22海蓝宝石
日期:2012-02-20 19:24:27铁扇公主
日期:2012-02-21 15:03:13
发表于 2017-5-4 10:24 | 显示全部楼层
ACD

A: S 定义长度为9,符合的两个S拼接起来长度不超过9的,有 101,104,109
   LOG ERRORS REJECT LIMIT UNLIMITED 错误记录不限制 所以OK
B: LOG ERRORS REJECT LIMIT 3 ,限制了错误记录数,超过3就走例外了
C:利用最高最低俩个集合变量,将数据分为了4组,大小 3,3,3,1
   每次update,都不会超过3行,所以不会报错
D: 与C 不同的是将for改为了forall,但 LIMIT UNLIMITED 错误记录不限制 所以OK
E: 与D不同的是LIMIT UNLIMITED 改成了 LIMIT 3 ,
   但重点是forall 是一次性将SQL提交到SQL引擎,LOG ERRORS REJECT LIMIT 是累计计数的,
   数据按顺序更新到104就会报错走例外
F: 数据分为了2组,但原因与E同
   

使用道具 举报

回复
论坛徽章:
527
奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:532009日食纪念
日期:2009-07-22 09:30:00
 楼主| 发表于 2017-5-5 03:47 | 显示全部楼层
答案ACD, 2楼得奖。

AD: 对错误的数量没有任何限制,UPDATE能够成功执行,有三行被修改,七行修改失败。
B: 将错误限制为3, 就意味着第四个错误会导致修改失败,所有成功的修改被回滚,只会在错误日志中留下四行失败记录。
C: 每个单独的修改都成功了,因为每个修改的集合中失败的行数都小于四,最终我们有三行成功修改,七行失败。
E: 和FOR LOOP不同,FORALL用的是数组处理方式,在一个批次中处理所有的修改,错误限制是作为一个整体应用在FORALL之上的。因为没有SAVE EXCEPTIONS子句,第四个错误发生之后FORALL失败了。然而,因为我们处理了异常,只有第二个不成功的UPDATE语句被回滚,最后我们得到的是第一个成功的UPDATE语句,有一行数据被修改。
F: 如同前一选项,错误限制是作为一个整体应用在FORALL之上的,而回滚则是应用于FORALL索引值,所以我们在第一个集合中有两行被成功修改,而总共只有四个错误被记录。

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则 发表回复

【有奖讨论】解决存储挑战了解一下
奖品:米家车载空气净化器 、米家声波电动牙刷 、小米运动蓝牙耳机

在数字经济时代,井喷式增长的数据,在释放大量商业价值的同时,也随之对企业的IT基础设施带来了不容忽视的挑战!如何存储、管理、使用这些数据呢?这是一条比以往更艰难的路~

活动时间:9月20日-10月11日

参与讨论>>
TOP技术积分榜 社区积分榜 徽章 团队 统计 知识索引树 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛
CopyRight 1999-2011 itpub.net All Right Reserved. 北京盛拓优讯信息技术有限公司版权所有 联系我们 
京ICP备16024965号 北京市公安局海淀分局网监中心备案编号:11010802021510 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表