ITPUB论坛-中国专业的IT技术社区

 找回密码
 注册
查看: 4879|回复: 6

[每日一题] PL/SQL Challenge 每日一题:2017-3-24 动态PL/SQL块

[复制链接]
论坛徽章:
496
紫蜘蛛
日期:2007-09-26 17:05:56奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:53
发表于 2017-3-29 04:28 | 显示全部楼层 |阅读模式

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我执行了下列语句:

CREATE TABLE my_data (n NUMBER, s VARCHAR2(100))
/

BEGIN
   INSERT INTO my_data VALUES (100, 'aba');
   COMMIT;
END;
/

哪些选项在执行的时候会发生异常?(注意是要挑选出哪些会报错)

(A)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE 'SELECT n FROM my_data WHERE s LIKE :my_s';
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str INTO l_n USING 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/

(B)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE 'SELECT n FROM my_data WHERE s LIKE :my_s'
      USING :my_s;
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str INTO l_n USING 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/

(C)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := '
SELECT n FROM my_data WHERE s LIKE :my_s';

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str INTO l_n USING IN 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/

(D)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE 'SELECT n FROM my_data WHERE s LIKE :my_s'
      INTO :my_n
      USING :my_s;
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str USING IN 'a%', OUT l_n;

   DBMS_OUTPUT.put_line (l_n);
END;
/

(E)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE 'SELECT n FROM my_data WHERE s LIKE :my_s'
      INTO :my_n
      USING :my_s;
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str USING IN 'a%', OUT l_n, IN 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/

(F)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE 'SELECT n FROM my_data WHERE s LIKE :my_s'
      INTO :my_n
      USING :my_s;
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str USING OUT l_n, IN 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/

(G)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE '
      BEGIN
         SELECT n INTO :my_n FROM my_data WHERE s LIKE :my_s;
      END;'
      INTO :my_n USING :my_s;
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str USING OUT l_n, IN 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/

(H)
DECLARE
   str   CONSTANT VARCHAR2 (500)
      := q'[
BEGIN
   EXECUTE IMMEDIATE '
      BEGIN
         SELECT n INTO :my_n FROM my_data WHERE s LIKE :my_s;
      END;'
      USING OUT :my_n, IN :my_s;
END;]' ;

   l_n  my_data.n%TYPE;
BEGIN
   EXECUTE IMMEDIATE str USING OUT l_n, IN 'a%';

   DBMS_OUTPUT.put_line (l_n);
END;
/
认证徽章
论坛徽章:
21
林肯
日期:2013-07-30 18:00:55秀才
日期:2018-05-22 15:17:21秀才
日期:2018-05-22 15:21:20技术图书徽章
日期:2018-05-22 15:21:47秀才
日期:2018-05-22 15:21:47秀才
日期:2018-05-22 16:13:08秀才
日期:2018-05-22 16:13:21技术图书徽章
日期:2018-05-22 16:13:30秀才
日期:2018-05-22 16:13:30技术图书徽章
日期:2018-05-22 15:17:21
发表于 2017-3-29 08:30 | 显示全部楼层
到了单位研究一下
来自苹果客户端来自客户端

使用道具 举报

回复
论坛徽章:
400
紫蛋头
日期:2012-05-21 10:19:41迷宫蛋
日期:2012-06-06 16:02:49奥运会纪念徽章:足球
日期:2012-06-29 15:30:06奥运会纪念徽章:排球
日期:2012-07-10 21:24:24鲜花蛋
日期:2012-07-16 15:24:59奥运会纪念徽章:拳击
日期:2012-08-07 10:54:50奥运会纪念徽章:羽毛球
日期:2012-08-21 15:55:33奥运会纪念徽章:蹦床
日期:2012-08-21 21:09:51奥运会纪念徽章:篮球
日期:2012-08-24 10:29:11奥运会纪念徽章:体操
日期:2012-09-07 16:40:00
发表于 2017-3-29 12:53 | 显示全部楼层
主要考绑定变量问题

使用道具 举报

回复
论坛徽章:
1
秀才
日期:2017-04-05 13:27:59
发表于 2017-3-29 13:04 | 显示全部楼层
代码不能高亮吗?

使用道具 举报

回复
论坛徽章:
44
秀才
日期:2016-04-29 15:03:39秀才
日期:2018-01-02 15:29:54秀才
日期:2018-01-02 15:29:54秀才
日期:2018-01-02 15:29:54秀才
日期:2018-01-02 15:35:05秀才
日期:2018-01-02 15:35:50秀才
日期:2018-01-02 15:35:50秀才
日期:2018-01-02 15:35:50状元
日期:2018-01-03 13:36:41榜眼
日期:2018-01-03 13:36:41
发表于 2017-3-29 13:26 | 显示全部楼层
我选ABDEG
C正确、直接使用绑定变量。
FH正确使用OUT绑定变量。
其他错误

使用道具 举报

回复
招聘 : 系统分析师
论坛徽章:
483
马上有房
日期:2014-02-19 11:55:14itpub13周年纪念徽章
日期:2014-09-28 10:55:55itpub13周年纪念徽章
日期:2014-09-29 01:14:14itpub13周年纪念徽章
日期:2014-10-08 15:15:25itpub13周年纪念徽章
日期:2014-10-08 15:15:25马上有对象
日期:2014-10-12 11:58:40马上有车
日期:2014-11-16 17:11:29慢羊羊
日期:2015-02-09 17:04:38沸羊羊
日期:2015-03-04 14:43:432015年新春福章
日期:2015-03-06 11:57:31
发表于 2017-3-29 14:36 | 显示全部楼层
好绕的题目,一不小心容易犯错

使用道具 举报

回复
论坛徽章:
496
紫蜘蛛
日期:2007-09-26 17:05:56奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:53
 楼主| 发表于 2017-3-30 04:50 | 显示全部楼层
答案ABDEG, 5楼得奖。

A:
这个选项会出错:
"ORA-01006: bind variable does not exist".
嗯?当我执行动态字符串的时候,我提供了一个绑定变量。在动态代码块里面有":my_s"。那么问题在哪?

问题在于,这个占位符是动态SELECT的占位符,它是在动态PL/SQL块里面执行的。USING子句提供的是动态PL/SQL块的占位符的绑定变量。但是":my_s"仅仅是代码块中的一个文本,,它并不会被当作是代码块的占位符。

B: 这个选项会出错:
"ORA-01007: variable not in select list".
那是因为我在一个PL/SQL块的EXECUTE IMMEDIATE中有一个INTO子句。INTO子句仅仅是给动态SELECT使用的。
C: 现在我的动态字符串仅仅是一个SELECT语句,不是一个包含动态SELECT的PL/SQL代码块。所以INTO和USING的使用没有问题,不会发生异常。

D:
这个选项会出错:
"ORA-06536: IN bind variable bound to an OUT position".
在动态PL/SQL块中,":my_n" 占位符出现在":my_s"之前,因为它是在一个INTO子句之中,它必须是OUT模式。但它必须是USING列表中的第一个而不是第二个。

E: 这个选项会报错:
"ORA-01006: bind variable does not exist".
在动态PL/SQL块中只有两个占位符,第一个的":my_s"实际上是在动态PL/SQL块中的动态SELECT字符串中的占位符。

F: 现在,我在USING子句中仅有两个绑定变量,第一个是OUT, 第二个是IN, 这和动态PL/SQL块中的使用情况相符。
G: 这个选项会报错:
"ORA-01008: not all variables bound".

现在,我有一个动态PL/SQL块,它执行一个动态PL/SQL块,而那个动态PL/SQL块又执行一个SELECT-INTO。天哪!
问题出在这行:

INTO :my_n USING :my_s;

这是一个动态PL/SQL块,所以INTO没有意义,并且你在USING子句中需要两个元素。

H: 这个代码块执行不会出错,因为两个USING子句都有正确的元素个数和正确的模式。

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则

TOP技术积分榜 社区积分榜 徽章 电子杂志 团队 统计 虎吧 老博客 知识索引树 读书频道 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档 | IT博客
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛 | SAP ERP系统
CopyRight 1999-2011 itpub.net All Right Reserved. 北京盛拓优讯信息技术有限公司版权所有 联系我们 网站律师 隐私政策 知识产权声明
京ICP备16024965号 北京市公安局海淀分局网监中心备案编号:11010802021510 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表