ITPUB论坛-中国最专业的IT技术社区

 找回密码
 注册
查看: 2664|回复: 2

[每日一题] PL/SQL Challenge 每日一题:2017-3-21 在FORALL中使用动态SQL

[复制链接]
论坛徽章:
453
秀才
日期:2015-08-18 09:49:27举人
日期:2015-09-09 10:34:21秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01状元
日期:2015-09-09 10:34:21榜眼
日期:2015-09-09 10:34:21秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01
发表于 2017-3-24 04:44 | 显示全部楼层 |阅读模式
(原发表于 2011-6-27)
最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我们有许多类似的零部件表(我知道,这是很糟糕的设计,但现在我们陷在里面了)。这里有两个这种表的例子以及数据:

CREATE TABLE plch_parts1
(
  partnum    INTEGER PRIMARY KEY
, partname   VARCHAR2 (100) UNIQUE
)
/

BEGIN
   INSERT INTO plch_parts1
        VALUES (1, 'Mouse');

   COMMIT;
END;
/

CREATE TABLE plch_parts2
(
  partnum    INTEGER PRIMARY KEY
, partname   VARCHAR2 (100) UNIQUE
)
/

BEGIN
   INSERT INTO plch_parts2
        VALUES (2000, 'Lens');
   COMMIT;
END;
/

现在我想要写一个过程来从这些零部件表中删除数据。我差不多写好了,现在我只需要加一个FORALL语句:


CREATE OR REPLACE PROCEDURE plch_clean_up_table (
   table_name_in   IN VARCHAR2
, ids_in          IN DBMS_SQL.number_table)
IS
BEGIN
   /*FORALL_HERE*/

   DBMS_OUTPUT.put_line (SQL%ROWCOUNT);
END;
/

哪些选项可用来取代/*FORALL_HERE*/注释,使得过程编译后,下列代码块被执行,数字 1 会被显示两次?

DECLARE
   l_ids   DBMS_SQL.number_table;
BEGIN
   l_ids (1) := 1;
   plch_clean_up_table ('plch_parts1', l_ids);

   l_ids (1) := 2000;
   plch_clean_up_table ('plch_parts2', l_ids);
END;
/

(A)
FORALL indx IN 1 .. ids_in.COUNT
   EXECUTE IMMEDIATE
      'DELETE FROM ' || table_name_in ||
      ' WHERE partnum = :id'
      USING ids_in (indx);

(B)
FORALL indx IN 1 .. ids_in.COUNT
   EXECUTE IMMEDIATE
      'DELETE FROM ' || table_name_in ||
      ' WHERE partnum = :id'
      USING ids_in;


(C)
FORALL indx IN 1 .. ids_in.COUNT
   EXECUTE IMMEDIATE
      'DELETE FROM ' || table_name_in ||
      ' WHERE partnum = ids_in (:index)'
      USING indx;


(D)
FORALL indx IN 1 .. ids_in.COUNT
   EXECUTE IMMEDIATE
      'DELETE FROM ' || table_name_in
   || ' WHERE partnum = :ids (:index)'
      USING ids_in, indx;

论坛徽章:
1
秀才
日期:2017-04-05 13:27:59
发表于 2017-3-24 12:52 | 显示全部楼层
选 A

A: ids_in (indx)与:id对应,正确。
B: 不能将数组绑定到动态SQL,错误
C: 动态SQL无法识别ids_in,错误
D: 和B选项类似。错误

使用道具 举报

回复
论坛徽章:
453
秀才
日期:2015-08-18 09:49:27举人
日期:2015-09-09 10:34:21秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01状元
日期:2015-09-09 10:34:21榜眼
日期:2015-09-09 10:34:21秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01
 楼主| 发表于 2017-3-25 04:41 | 显示全部楼层
答案A, 2楼得奖。

A: 这个选项正确地在USING子句中引用了绑定数组和迭代变量。它会允许两张表上的删除都能够成功执行。
B: 这个选项在USING子句中引用了绑定数组,这没问题,但是它没有包含迭代变量,如下:

ids_in (indx)

结果,Oracle会试图将一个关联数组绑定到partnum的占位符,并且在编译的时候会报错:
"PLS-00457: expressions have to be of SQL types"

C: 这个选项在动态SQL语句中直接引用了绑定数组ids_in。如果过程编译了,语句被执行了,它会报错,因为SQL引擎不能识别对ids_in的引用。然而它还到不了那一步。试图编译这个过程会报错:
"PLS-00430: FORALL iteration variable INDX is not allowed in this context"
换言之,在FORALL里面迭代变量仅仅能够被用于绑定数组的索引值。

D: 过程编译的时候会报错:
"PLS-00457: expressions have to be of SQL types"
你不能将一个关联数组绑定到一个动态SQL语句。这些类型的数据只能 用于PL/SQL代码。

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则

久等啦!10张门票开启你的DTCC2017之旅~

2017中国数据库技术大会将于2017年5月11-13日如约而至,本届大会以“数据驱动•价值发现”为主题,共设定2大主场和21个技术专场,云集海内外120+位技术大牛,共同探讨Oracle、MySQL、NoSQL、云端数据库、区块链、深度学习等领域的前瞻性热点话题。
即日起,填写DTCC2017会前调查问卷,即有机会赢取价值2600元的大会门票1张!仅限10张!
----------------------------------------
活动截止时间:2017年5月5日统一公布

问卷入口>>
TOP技术积分榜 社区积分榜 徽章 电子杂志 团队 统计 虎吧 老博客 知识索引树 读书频道 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档 | IT博客
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛 | SAP ERP系统
CopyRight 1999-2011 itpub.net All Right Reserved. 北京皓辰网域网络信息技术有限公司版权所有 联系我们 网站律师 隐私政策 知识产权声明
京ICP证:060528号 北京市公安局海淀分局网监中心备案编号:1101082001 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表