ITPUB论坛-中国最专业的IT技术社区

 找回密码
 注册
查看: 4478|回复: 3

[每日一题] PL/SQL Challenge 每日一题:2017-3-8 批量读取 SELECT ... BULK COLLECT INTO

[复制链接]
论坛徽章:
454
秀才
日期:2015-08-18 09:49:27秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01状元
日期:2015-09-09 10:34:21榜眼
日期:2015-09-09 10:34:21秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01
发表于 2017-3-11 05:50 | 显示全部楼层 |阅读模式

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

每两周的优胜者可获得itpub奖励的技术图书一本。

以往旧题索引:
http://www.itpub.net/forum.php?m ... eid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我执行了下列语句:

CREATE TABLE qz_games
(
   game_id       INTEGER,
   game_name     VARCHAR2 (100),
   max_players   INTEGER,
   minimum_age   INTEGER
)
/

BEGIN
   INSERT INTO qz_games
        VALUES (1, 'Set', 6, 5);

   INSERT INTO qz_games
        VALUES (2, 'Chutes and Ladders', 4, 3);

   INSERT INTO qz_games
        VALUES (3, 'Chess', 2, 6);

   INSERT INTO qz_games
        VALUES (4, 'Trivial Pursuit', 4, 12);
   COMMIT;
END;
/

哪些选项的代码块在执行之后会显式下列两行文本(并且没有任何其它来自DBMS_OUTPUT缓冲区的文本)?

4-3
2-6

(A)
DECLARE
   TYPE max_and_min_rt IS RECORD
   (
      max_players   qz_games.max_players%TYPE,
      minimum_age   qz_games.minimum_age%TYPE
   );

   TYPE max_and_min_t IS TABLE OF max_and_min_rt
      INDEX BY PLS_INTEGER;

   l_max_mins   max_and_min_t;
BEGIN
     SELECT max_players, minimum_age
       BULK COLLECT INTO l_max_mins
       FROM qz_games
      WHERE game_name LIKE 'C%'
   ORDER BY game_id;
   
   FOR indx IN 1 .. l_max_mins.COUNT
   LOOP
      DBMS_OUTPUT.put_line (
         l_max_mins (indx).max_players
                     || '-'
                     || l_max_mins (indx).minimum_age);
   END LOOP;
END;
/

(B)
DECLARE
   TYPE integers_t IS TABLE OF INTEGER
      INDEX BY PLS_INTEGER;

   l_max_players   integers_t;
   l_min_ages      integers_t;
BEGIN
     SELECT max_players, minimum_age
       BULK COLLECT INTO l_max_players, l_min_ages
       FROM qz_games
      WHERE game_name LIKE 'C%'
   ORDER BY game_id;

   FOR indx IN 1 .. l_max_players.COUNT
   LOOP
      DBMS_OUTPUT.put_line (
         l_max_players (indx) || '-' || l_min_ages (indx));
   END LOOP;
END;
/

(C)
DECLARE
   TYPE integers_t IS TABLE OF INTEGER
      INDEX BY PLS_INTEGER;

   l_info    VARCHAR2 (32767);
   l_start   INTEGER := 1;
   l_end     INTEGER := 1;
BEGIN
   SELECT LISTAGG (max_players || '-' || minimum_age, ',')
             WITHIN GROUP (ORDER BY game_id)
     INTO l_info
     FROM qz_games
    WHERE game_name LIKE 'C%';

   LOOP
      EXIT WHEN l_end = 0;
      l_end := INSTR (l_info, ',', l_start);

      IF l_end = 0
      THEN
         DBMS_OUTPUT.put_line (SUBSTR (l_info, l_start));
      ELSE
         DBMS_OUTPUT.put_line (
            SUBSTR (l_info, l_start, l_end - l_start + 1));
      END IF;

      l_start := l_end + 1;
   END LOOP;
END;
/
论坛徽章:
18
秀才
日期:2016-04-29 15:11:10秀才
日期:2017-04-05 13:27:59秀才
日期:2017-04-05 13:23:10秀才
日期:2017-04-05 13:23:10秀才
日期:2017-04-05 13:23:10秀才
日期:2017-04-05 13:22:59秀才
日期:2017-03-02 10:35:32秀才
日期:2017-01-20 11:06:21秀才
日期:2017-01-20 11:00:36秀才
日期:2017-01-20 11:04:31
发表于 2017-3-11 09:49 | 显示全部楼层
我选AB
A、集合中存放两列数据这是可以的
B、存放两个单列集合也是可以的
C、通过字符串分割的方式也是可以,不过取子字符串的位置不对,所以错误,当然这样的方式也不推荐。

使用道具 举报

回复
论坛徽章:
393
雪佛兰
日期:2013-12-04 20:30:02马上有钱
日期:2014-03-11 11:59:122014年世界杯参赛球队:喀麦隆
日期:2014-07-11 12:10:53马上有对象
日期:2014-04-09 16:19:542014年世界杯参赛球队: 洪都拉斯
日期:2014-06-25 08:25:55itpub13周年纪念徽章
日期:2014-09-28 10:55:55itpub13周年纪念徽章
日期:2014-10-01 15:27:22itpub13周年纪念徽章
日期:2014-10-09 12:04:18马上有钱
日期:2014-10-14 21:37:37马上有钱
日期:2015-01-22 00:39:13
发表于 2017-3-13 20:32 | 显示全部楼层
第3种先连接后拆分真麻烦,还容易错

使用道具 举报

回复
论坛徽章:
454
秀才
日期:2015-08-18 09:49:27秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01状元
日期:2015-09-09 10:34:21榜眼
日期:2015-09-09 10:34:21秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01秀才
日期:2015-09-09 10:33:01
 楼主| 发表于 2017-3-14 04:37 | 显示全部楼层
答案AB, 2楼得奖。

A:(推荐)
我将两个列的值批量读取到一个记录的集合,这个集合是为此目的定制的。这使得代码更加简洁并且易于管理。
B:(不推荐)
在这个例子中,我批量读取到两个集合。你当然可以这么做,但是你就得保持两个集合的数据同步(为同行的行保持同样的索引值),你还得声明两个(或者更多)的集合。最好用一个记录的集合。
C:
有点小聪明。我用了LISTAGG来获得一个字符串,含有每一对值,用逗号隔开。这很花哨,如果我不必写解析代码来将每个数值对分离出来显示,那么也许可以这么干。

但是那意味着我得写一堆讨厌的代码,而bug很容易混进去。实际上,那正是这个选项错误的原因,这个算法要求"4-3"后面有个逗号。
最后,我将显示"信息"(即'-')嵌入了获取数据的代码中。这应该是分开的。

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则

TOP技术积分榜 社区积分榜 徽章 电子杂志 团队 统计 虎吧 老博客 知识索引树 读书频道 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档 | IT博客
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛 | SAP ERP系统
CopyRight 1999-2011 itpub.net All Right Reserved. 北京皓辰网域网络信息技术有限公司版权所有 联系我们 网站律师 隐私政策 知识产权声明
京ICP证:060528号 北京市公安局海淀分局网监中心备案编号:1101082001 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表