查看: 1808|回复: 3

[每日一题] PL/SQL Challenge 每日一题:2014-3-4 自治事务

[复制链接]
论坛徽章:
526
奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:532009日食纪念
日期:2009-07-22 09:30:00
发表于 2014-3-6 03:17 | 显示全部楼层 |阅读模式
本帖最后由 newkid 于 2014-3-6 06:43 编辑

最先答对且答案未经编辑的puber将获得纪念章一枚(答案不可编辑但可发新贴补充或纠正),其他会员如果提供有价值的分析、讨论也可获得纪念章一枚。

以往旧题索引:
http://www.itpub.net/forum.php?m ... =typeid&typeid=1808

原始出处:
http://www.plsqlchallenge.com/

作者:Steven Feuerstein

运行环境:SQLPLUS, SERVEROUTPUT已打开
注:本题给出答案时候要求给予简要说明才能得到奖品

我执行了这些语句:

CREATE TABLE plch_data (n NUMBER)
/

BEGIN
   INSERT INTO plch_data
        VALUES (500);

   COMMIT;
END;
/

CREATE TABLE plch_log (t VARCHAR2 (1000))
/

CREATE OR REPLACE PROCEDURE plch_show_info
IS
   l_count   INTEGER;
   l_n       NUMBER;
BEGIN
   SELECT n INTO l_n FROM plch_data;

   DBMS_OUTPUT.put_line ('N=' || l_n);

   SELECT COUNT (*) INTO l_count FROM plch_log;

   DBMS_OUTPUT.put_line ('L=' || l_count);
END;
/

哪些选项创建了一个名为PLCH_LOGGER的过程,使得下列代码块在执行之后会显示 "N=500" 和 "L=1" ?

BEGIN
   UPDATE plch_data
      SET n = n * 2;

   plch_logger ('Doubled!');

   ROLLBACK;

   plch_show_info;
END;
/



(A)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)
IS
   PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
   INSERT INTO plch_log
        VALUES (msg_in);

   COMMIT;
END;
/

(B)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)
IS
   PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
   INSERT INTO plch_log
        VALUES (msg_in);
END;
/

(C)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)
IS
BEGIN
   INSERT INTO plch_log
        VALUES (msg_in);

   COMMIT;
END;
/

(D)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)
IS
BEGIN
   INSERT INTO plch_log
        VALUES (msg_in);
END;
/



(E)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)
IS
   PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
   INSERT INTO plch_log
        VALUES (msg_in);
EXCEPTION
   WHEN OTHERS THEN
      COMMIT;
END;
/


(F)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)

IS
   PROCEDURE plch_local IS PRAGMA AUTONOMOUS_TRANSACTION;
   BEGIN
         INSERT INTO plch_log VALUES (msg_in);
         COMMIT;
   END;
BEGIN
   plch_local;
END;
/


(G)
CREATE OR REPLACE PROCEDURE plch_logger (msg_in IN VARCHAR2)
IS
   PROCEDURE plch_commit
   IS
      PRAGMA AUTONOMOUS_TRANSACTION;
   BEGIN
      COMMIT;
   END;
BEGIN
   INSERT INTO plch_log VALUES (msg_in);
   plch_commit;
END;
/


求职 : 数据库管理员
认证徽章
论坛徽章:
11
ITPUB社区千里马徽章
日期:2013-06-09 10:15:34懒羊羊
日期:2015-03-04 14:52:11懒羊羊
日期:2015-02-10 13:36:05马上有对象
日期:2015-02-02 12:29:02红宝石
日期:2015-01-19 09:44:10马上有车
日期:2014-11-11 14:16:07马上有车
日期:2014-03-27 15:59:39优秀写手
日期:2014-03-12 06:00:13马上有钱
日期:2014-02-18 16:43:092014年新春福章
日期:2014-02-18 16:43:09
发表于 2014-3-6 09:05 | 显示全部楼层
答案为A、F,就是一个自治事务不受外部rollback的影响。B没提交会报错,C都会提交,D都会回退,E输出N=1000,L=0,G的自治事务没有意义。

使用道具 举报

回复
论坛徽章:
526
奥运会纪念徽章:垒球
日期:2008-09-15 01:28:12生肖徽章2007版:鸡
日期:2008-11-17 23:40:58生肖徽章2007版:马
日期:2008-11-18 05:09:48数据库板块每日发贴之星
日期:2008-11-29 01:01:02数据库板块每日发贴之星
日期:2008-12-05 01:01:03生肖徽章2007版:虎
日期:2008-12-10 07:47:462009新春纪念徽章
日期:2009-01-04 14:52:28数据库板块每日发贴之星
日期:2009-02-08 01:01:03生肖徽章2007版:蛇
日期:2009-03-09 22:18:532009日食纪念
日期:2009-07-22 09:30:00
 楼主| 发表于 2014-3-7 04:15 | 显示全部楼层
答案AF, 2楼得奖。

A: 我往日志表(LOG)插入了数据并且提交。既然这是一个自治事务程序,插入被提交而外部的修改却不然,所以回滚撤销了修改。

B: 这个选项会报错: "ORA-06519: active autonomous transaction detected and rolled back"
如果一个自治事务程序的DML修改了数据,你在离开的时候必须提交或者回滚。

C: 既然这个程序不是自治事务,提交将会将插入和外部块的修改同时保存。因此它会显示:
N=1000
L=1

D: 在这个日志过程里没有提交,所以外部块的回滚会将插入和修改同时撤销,因此会显示:
N=500
L=0

E: 既然执行部分没有提交,插入也不出错,过程终止的时候会报这个错:
ORA-06519: active autonomous transaction detected and rolled back
可是这个错误被处理掉,并且执行了提交——但提交发生在自治事务之外,因此外部块的修改被提交,日志表中却没有数据。输出是:
N=1000
L=1

F: 插入和提交被放到一个嵌套子程序内部,它仍然在plch_logger的范围之内,所以表现是相同的。
G: 提交发生在一个嵌套的自治事务子程序内部,所以它实际上并没有保存两层外部代码的任何修改。

使用道具 举报

回复
论坛徽章:
403
紫蛋头
日期:2012-05-21 10:19:41迷宫蛋
日期:2012-06-06 16:02:49奥运会纪念徽章:足球
日期:2012-06-29 15:30:06奥运会纪念徽章:排球
日期:2012-07-10 21:24:24鲜花蛋
日期:2012-07-16 15:24:59奥运会纪念徽章:拳击
日期:2012-08-07 10:54:50奥运会纪念徽章:羽毛球
日期:2012-08-21 15:55:33奥运会纪念徽章:蹦床
日期:2012-08-21 21:09:51奥运会纪念徽章:篮球
日期:2012-08-24 10:29:11奥运会纪念徽章:体操
日期:2012-09-07 16:40:00
发表于 2014-3-7 08:49 | 显示全部楼层
其他数据库也支持?

使用道具 举报

回复

您需要登录后才可以回帖 登录 | 注册

本版积分规则 发表回复

TOP技术积分榜 社区积分榜 徽章 团队 统计 知识索引树 积分竞拍 文本模式 帮助
  ITPUB首页 | ITPUB论坛 | 数据库技术 | 企业信息化 | 开发技术 | 微软技术 | 软件工程与项目管理 | IBM技术园地 | 行业纵向讨论 | IT招聘 | IT文档
  ChinaUnix | ChinaUnix博客 | ChinaUnix论坛
CopyRight 1999-2011 itpub.net All Right Reserved. 北京盛拓优讯信息技术有限公司版权所有 联系我们 
京ICP备09055130号-4  北京市公安局海淀分局网监中心备案编号:11010802021510 广播电视节目制作经营许可证:编号(京)字第1149号
  
快速回复 返回顶部 返回列表