汉字转拼音的Oracle函数

〇〇 · 发表于 2013-3-22 11:00

samt007 发表于 2013-3-22 10:52
请问是哪个函数？找不到。。。如果有Oracle的标准函数就更好了。

SQL> select TO_multi_BYTE ('123abc,.;') from dual;

TO_MULTI_BYTE('123
------------------
１２３ａｂｃ，．；

已用时间: 00: 00: 00.01
SQL> select to_single_byte('１２３ａｂｃ，．；') from dual;

TO_SINGLE
---------
123abc,.;

samt007 · 发表于 2013-3-22 11:07

本帖最后由 samt007 于 2013-3-22 11:08 编辑

嗯，谢谢指点。我看了一下，可以实现单字节的转换；但是如果要实现汉字-->拼音的转换是不行的。。。
我这里主要的目的是想实现汉字转拼音。因为图片文件名如果有中文，Form读取不了。

select to_single_byte ('我们') from dual;
----
我们

samt007 · 发表于 2013-3-22 11:11

不过是可以补充在我的转换函数里面。。。完整函数的获取逻辑。

samt007 · 发表于 2013-3-22 11:17

select to_single_byte ('“') from dual;
这个貌似转换不了，奇怪。不是所有符号都可以转换。。。

samt007 · 发表于 2013-3-22 11:21

修改后的函数。其实改动很小：
function get_chinese_Spell(p_cnStr In varchar2
                     ,P_SEPARATOR In varchar2 Default Null--输出汉字的分隔符
                     ,p_output_type In varchar2 Default Null--输出格式，是首字大写FIRST还是全部FULL
                     ,P_CASE_TYPE IN VARCHAR2 DEFAULT 'LOWER'---输出汉字的拼音的格式，小写，大写还是首字母大写INITCAP。
                     ,P_UNKNOW_SPELL VARCHAR2 DEFAULT '#'---识别不了的用哪个字符显示
                     ,P_RAISE    IN NUMBER DEFAULT XYG_PUB_CONST_PKG.C_TRUE) return varchar2
as
   lv_spell varchar2(3000);
   lv_temp Varchar2(100);
   lv_char varchar2(100);
   ---
   lv_exists_cn boolean;--是否存在汉字的

   ---获取单个的拼音
   Function get_signle_spell(P_SIGNLE_CHINESE IN VARCHAR2) return VARCHAR2
   is
      l_return XYG_chinese_Spell.CHINESE_SPELL%TYPE;
   begin
   SELECT XCS1.CHINESE_SPELL
      INTO l_return
      FROM XYG_chinese_Spell XCS1
      WHERE XCS1.CHINESE_Spell_ID =
            (SELECT MAX(XCS2.CHINESE_Spell_ID)
            FROM XYG_chinese_Spell XCS2
            WHERE XCS2.CHINESE_WORD LIKE '%'||P_SIGNLE_CHINESE||'%');
   RETURN l_return;
   EXCEPTION
      WHEN OTHERS THEN
      RETURN P_UNKNOW_SPELL;
   end;
begin
   if p_cnStr is null then
      return '';
   end if;
   lv_exists_cn := false;
   for i In 1..length(p_cnStr) loop
      ---先自动转换。to_single_byte转换为单字节。2013.3.22 new add by sam.t
      ---PS:TO_multi_BYTE 是反转的。
      lv_char:=to_single_byte(substr(p_cnStr,i,1));
      if lengthb(lv_char) = 1 then
         if lv_exists_cn then
            lv_spell:=lv_spell||P_SEPARATOR||lv_char;
            lv_exists_cn := false;
         else
            lv_spell:=lv_spell||lv_char;
         end if;
      else--汉字：
         ----如果是常用的符号，也要转换。只是单对单的转换。
         if lv_char = '，' then--逗号
         lv_temp := ',';
         elsif lv_char = '。' then--句号
         lv_temp := '.';
         elsif lv_char = '？' then--问号
         lv_temp := '?';
         elsif lv_char = '！' then--感叹号
         lv_temp := '!';
         elsif lv_char = '‘' then--单引号
         lv_temp := '''';
         elsif lv_char = '“' then--双引号
         lv_temp := '"';
         elsif lv_char = '；' then--分号
         lv_temp := ';';
         elsif lv_char = '：' then--冒号
         lv_temp := ':';
         else
         lv_exists_cn := true;
         lv_temp := get_signle_spell(lv_char);
         IF P_CASE_TYPE = 'LOWER' THEN
            lv_temp := LOWER(lv_temp);
         ELSIF P_CASE_TYPE = 'UPPER' THEN
            lv_temp := UPPER(lv_temp);
         ELSIF P_CASE_TYPE = 'INITCAP' THEN
            lv_temp := INITCAP(lv_temp);
         ELSE
            NULL;
         END IF;
         end if;


         if p_output_type = 'FIRST' then
            lv_spell:=lv_spell||P_SEPARATOR||substr(lv_temp,1,1);
         else
            lv_spell:=lv_spell||P_SEPARATOR||lv_temp;
         end if;
      end if;
   end loop;

   ---将左边的分隔符去掉
   IF P_SEPARATOR IS NOT NULL THEN
   lv_spell := LTRIM(lv_spell,P_SEPARATOR);
   END IF;
   return lv_spell;
end;