PL/SQL CHALLENGE 每日一题

tnarp

A

newkid

2011-11-17答案C.
一个定义为调用者权限（AUTHID CURRENT_USER）的函数，如果它在一个VIEW或者触发器中被调用，这时是按照定义者的权限来运作的，所以你通过VIEW看到的将是OWNER的数据，而不是当前用户的数据。
=====================================

2011-11-18 触发器中的:NEW 和 :OLD
作者：Steven Feuerstein
难度：低

我创建了这两张表，并在plch_parts表中加了两行数据:

CREATE TABLE plch_parts
(
   partnum    NUMBER
,  partname   VARCHAR2 (50)
)
/

BEGIN
   INSERT INTO plch_parts
        VALUES (123, 'Steering Wheel');

   INSERT INTO plch_parts
        VALUES (456, 'Brake Pedal');

   COMMIT;
END;
/

CREATE TABLE plch_log
(
   partnum      NUMBER
,  partname     VARCHAR2 (50)
,  changed_on   DATE
,  changed_by   VARCHAR2 (100)
)
/

然后我在 plch_parts 表上加了个触发器:
CREATE OR REPLACE TRIGGER plch_parts_trig
   AFTER UPDATE
   ON plch_parts
   FOR EACH ROW
DECLARE
BEGIN
   INSERT INTO plch_log
        VALUES (:new.partnum
              ,  :new.partname
              ,  SYSDATE
              ,  USER);
END plch_parts_trig;
/

然后我执行了这个块:
BEGIN
   UPDATE plch_parts
      SET partnum = -1 * partnum
    WHERE partname = 'Brake Pedal';

   UPDATE plch_parts
      SET partname = UPPER (partname)
    WHERE partnum = 123;
   COMMIT;
END;
/

下列选项哪些显示了这个查询的结果：
SELECT partnum, partname
    FROM plch_log
ORDER BY partnum
/

(A)
   PARTNUM PARTNAME                                          
---------- ------------------
      -456 Brake Pedal                                       
       123 STEERING WHEEL  
(B)
   PARTNUM PARTNAME                                          
---------- ------------------
       123 Steering Wheel
       456 Brake Pedal            
                     
(C)
   PARTNUM PARTNAME                                          
---------- ------------------
       123 STEERING WHEEL  
       456 Brake Pedal     

(D)
   PARTNUM PARTNAME                                          
---------- ------------------
       123 STEERING WHEEL  
      -456 Brake Pedal        

jboracle1981

A

solomon_007

A

solomon_007

newkid 发表于 2011-11-22 01:12
2011-11-17答案B.
一个定义为调用者权限（AUTHID CURRENT_USER）的函数，如果它在一个VIEW或者触发器中被调 ...

2011-11-17 我今天验证得到结果是 C


SQL> set serveroutput on;
SQL>
SQL> CREATE TABLE plch_parts
  2  (
  3     partnum    NUMBER
  4  , partname   VARCHAR2 (50)
  5  )
  6  /

Table created

SQL>
SQL> BEGIN
  2     INSERT INTO plch_parts
  3          VALUES (123, 'Steering Wheel');
  4  
  5     INSERT INTO plch_parts
  6          VALUES (456, 'Brake Pedal');
  7  
  8     COMMIT;
  9  END;
10  /

PL/SQL procedure successfully completed

SQL> CREATE OR REPLACE TYPE plch_numbers_t IS TABLE OF NUMBER
  2  /

Type created

SQL>
SQL> CREATE OR REPLACE FUNCTION plch_func
  2     RETURN plch_numbers_t
  3     AUTHID CURRENT_USER
  4  IS
  5     l_numbers   plch_numbers_t;
  6  BEGIN
  7     SELECT partnum
  8       BULK COLLECT INTO l_numbers
  9       FROM plch_parts;
10  
11     RETURN l_numbers;
12  END;
13  /

Function created

SQL>
SQL> CREATE OR REPLACE VIEW plch_func_v
  2  AS
  3     SELECT COLUMN_VALUE partnum FROM TABLE (plch_func ())
  4  /

View created

SQL> GRANT SELECT ON plch_func_v TO scott
  2  /

Grant succeeded

SQL> GRANT EXECUTE ON plch_func TO scott
  2  /

Grant succeeded

SQL> conn scott/tiger;
Connected to Oracle Database 10g Enterprise Edition Release 10.2.0.4.0
Connected as scott

SQL>
SQL> CREATE TABLE plch_parts
  2  (
  3     partnum    NUMBER
  4  , partname   VARCHAR2 (50)
  5  )
  6  /

Table created

SQL>
SQL> BEGIN
  2     INSERT INTO plch_parts
  3          VALUES (100, 'Tire');
  4  
  5     INSERT INTO plch_parts
  6          VALUES (101, 'Battery');
  7  
  8     COMMIT;
  9  END;
10  /

PL/SQL procedure successfully completed


SQL> set serveroutput on size 1000000;
SQL>
SQL> BEGIN
  2     DBMS_OUTPUT.put_line ('Two Cursor For Loops....');
  3  
  4     FOR rec IN (  SELECT p.partname
  5                     FROM TABLE (hr.plch_func) v, plch_parts p
  6                    WHERE v.column_value = p.partnum
  7                 ORDER BY p.partnum)
  8     LOOP
  9        DBMS_OUTPUT.put_line (rec.partname);
10     END LOOP;
11  
12     FOR rec IN (  SELECT p.partname
13                     FROM hr.plch_func_v v, plch_parts p
14                    WHERE v.partnum = p.partnum
15                 ORDER BY p.partnum)
16     LOOP
17        DBMS_OUTPUT.put_line (rec.partname);
18     END LOOP;
19  END;
20  /

Two Cursor For Loops....
Tire
Battery

PL/SQL procedure successfully completed

newkid

solomon_007 发表于 2011-11-22 11:21
2011-11-17 我今天验证得到结果是 C

确实是C, 我笔误写成了B, 已经改过来了。
2011-11-18答案A, 这个很简单。
=========================
2011-11-21 未捕获异常
作者：Steven Feuerstein
难度：中

下列哪些选项在执行之后会导致未捕获的异常：
ORA-06502: PL/SQL: numeric or value error: number precision too large

(A)
DECLARE
   l_number   NUMBER (2) := 100;
BEGIN
   DBMS_OUTPUT.put_line (l_number);
END;
/

(B)
DECLARE
   l_number   NUMBER (2) := 100;
BEGIN
   DBMS_OUTPUT.put_line (l_number);
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line ('ERROR');
END;
/
                     
(C)
CREATE OR REPLACE PACKAGE plch_pkg
IS
   FUNCTION get_number
      RETURN NUMBER;
END;
/

CREATE OR REPLACE PACKAGE BODY plch_pkg
IS
   g_date     DATE;
   g_number   NUMBER (2) := 100;

   FUNCTION get_number
      RETURN NUMBER
   IS
   BEGIN
      RETURN g_number;
   END;
BEGIN
   g_date := SYSDATE;
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line ('ERROR');
END;
/

DECLARE
   l_number   NUMBER (2) := plch_pkg.get_number;
BEGIN
   DBMS_OUTPUT.put_line (l_number);
END;
/

(D)
CREATE OR REPLACE PACKAGE plch_pkg
IS
   g_number   NUMBER (2) := 100;
END;
/

DECLARE
   l_number   NUMBER (2) := plch_pkg.g_number;
BEGIN
   DBMS_OUTPUT.put_line (l_number);
END;
/
      

lastwinner

喜欢这类型的东东，不用耗费太多心思在复杂的计算上，但却需要扎实的基础知识与实践功底

jboracle1981

AD

jboracle1981

肉流满面

solomon_007

ABCD