PL/SQL CHALLENGE 每日一题

newkid

2012-2-1 所有答案都不对。
A: 在这个实现方案中，和循环变量无关的代码被转移到循环之外。但是这并不会提高性能，因为在plsql_optimize_level的缺省设置（值为2）或者更高设置下，PLSQL的优化器已经自动替你做了这件事。
B: 在这个实现方案中，基于parts_in集合的计算先被赋值给一个变量，然后累加。这样做不会提高性能，原因同上，PLSQL优化器已经自动把这部分代码转移出循环了。
C: 这个设置(1)比缺省值(2)更低，所以实际上性能更差了，每次循环都会进行计算。
D: 同上。
==================================
2012-2-2 日期的四舍五入
作者：Steven Feuerstein
难度：低

我创建了这个过程来显示一个日期及时间的值：

CREATE OR REPLACE PROCEDURE plch_show_date (date_in IN DATE)
IS
BEGIN
   DBMS_OUTPUT.put_line (TO_CHAR (date_in, 'YYYY-MON-DD HH24:MI:SS'));
END;
/

我需要写一个名字叫plch_start_of_day的函数，它接受一个日期型参数，不妨称为date_in，然后根据如下规则返回一个日期：

1. 如果date_in的时间部分是正午时分或者更迟(12:00:00或以后)，那么函数返回值的日期部分必须是date_in+1。否则，返回值的日期部分和date_in相同。

2. 返回值的时间部分必须被设为午夜（即00:00）

下列的哪些选项实现了这样的行数，从而当我执行这个代码块时：
BEGIN
   plch_show_date (
      plch_start_of_day (
         TO_DATE ('2012-JAN-15 01:00:00', 'YYYY-MON-DD HH24:MI:SS')));
   plch_show_date (
      plch_start_of_day (
         TO_DATE ('2012-JAN-15 15:00:00', 'YYYY-MON-DD HH24:MI:SS')));
END;
/

我会看到这两行文本：
2012-JAN-15 00:00:00
2012-JAN-16 00:00:00

(A)
CREATE OR REPLACE FUNCTION plch_start_of_day (date_in IN DATE)
   RETURN DATE
IS
BEGIN
   RETURN ROUND (date_in, 'DDD');
END;
/

(B)
CREATE OR REPLACE FUNCTION plch_start_of_day (date_in IN DATE)
   RETURN DATE
IS
BEGIN
   RETURN ROUND (date_in, 'DAY');
END;
/

(C)
CREATE OR REPLACE FUNCTION plch_start_of_day (date_in IN DATE)
   RETURN DATE
IS
   c_seconds_to_noon   CONSTANT NUMBER := (24 * 60 * 60) / 2;
   c_seconds           CONSTANT NUMBER := TO_CHAR (date_in, 'SSSSS');
BEGIN
   RETURN
      CASE
         WHEN c_seconds >= c_seconds_to_noon THEN TRUNC (date_in + 1)
         ELSE TRUNC (date_in)
      END;
END;
/

(D)
CREATE OR REPLACE FUNCTION plch_start_of_day (date_in IN DATE)
   RETURN DATE
IS
BEGIN
   RETURN TRUNC (date_in);
END;
/

(E)
CREATE OR REPLACE FUNCTION plch_start_of_day (date_in IN DATE)
   RETURN DATE
IS
BEGIN
   RETURN ROUND (date_in);
END;
/

ycpriscilla

A、D、E

newkid

2012-2-2 答案 ACE
A: ROUND函数作用于日期型且带DDD作为格式参数，将会四舍五入（正午之前为舍，正午或之后为入），符合题意要求。
B: ROUND函数作用于日期型且带DAY作为格式参数，将会四舍五入(以星期三正午为界，之前为舍，正午或之后为入)到每周的周日。
C: 自己用CASE逻辑实现了题意
D: TRUNC只舍不入
E: ROUND函数作用于日期型且不带格式参数，将会四舍五入（正午之前为舍，正午或之后为入），符合题意要求。
=======================================
2012-2-3 集合去重
作者：Steven Feuerstein
难度：中

我创建了如下的类型：
CREATE OR REPLACE TYPE numbers_t IS TABLE OF NUMBER;
/

然后我写了如下代码块（未完成）：
DECLARE
   l_numbers   numbers_t
                  := numbers_t (1, 2, 3, 4, 3, 5);
BEGIN
   /*REMOVEDUPS*/

   FOR rec IN (  SELECT COLUMN_VALUE
                   FROM TABLE (l_numbers)
               ORDER BY COLUMN_VALUE)
   LOOP
      DBMS_OUTPUT.put_line (rec.COLUMN_VALUE);
   END LOOP;

   DBMS_OUTPUT.put_line (l_numbers.LAST);
END;
/

哪些选项提供了一个/*REMOVEDUPS*/注释的代替品，使得代码块执行之后会显示如下文本：
1
2
3
4
5
5

(A)
l_numbers := DISTINCT (l_numbers);

(B)
l_numbers := UNIQUE (l_numbers);

(C)
l_numbers := SET (l_numbers);

(D)
DECLARE
   l_used   DBMS_SQL.number_table;
BEGIN
   FOR indx IN 1 .. l_numbers.COUNT
   LOOP
      IF l_used.EXISTS (l_numbers (indx))
      THEN
         l_numbers.delete (indx);
      ELSE
         l_used (l_numbers (indx)) := 1;
      END IF;
   END LOOP;
END;

ycpriscilla

ycpriscilla 发表于 2012-2-4 12:26
A、D、E

晕，想的是C写的是D...

newkid

2012-2-3 答案C.
A,B:语法错误；D:虽然删除了重复数据，但是位置还空着。
========================================
2012-2-6
作者：Valentin Nikotin
难度：高

我创建了如下的函数：
create or replace function plch_func (i number) return number is
begin
  dbms_output.put_line('plch_func with i = '||i);
  return 1;
end;
/

下列的每个选项都包含一个代码块，它执行一个查询，查询中轮流调用这个plch_func函数。哪些选项会导致下列的两行文本被显示？（顺序无所谓）

plch_func with i = 1
plch_func with i = 2

(A)
declare
  val1 number;
  val2 number;
begin
  select plch_func(1), plch_func(2) into val1, val2
    from dual;
end;
/

(B)
begin
  for rec in (select plch_func(1), plch_func(2) from dual)
  loop
    null;
  end loop;
end;
/

(C)
begin
  execute immediate
    'select plch_func(1), plch_func(2)
       from dual';
end;
/

(D)
declare
  val1 number;
  val2 number;   
begin
  execute immediate
    'select plch_func(1), plch_func(2)
       from dual'
    into val1, val2;
end;
/

(E)
declare
  c number := dbms_sql.open_cursor;
  rc number;
begin
  dbms_sql.parse(c,
                 'select plch_func(1), plch_func(2) from dual',
                 dbms_sql.native);
  rc := dbms_sql.execute_and_fetch(c);
  dbms_sql.close_cursor(c);
end;
/


(F)
declare
  c number := dbms_sql.open_cursor;
  rc number;
begin
  dbms_sql.parse(c,
                 'select plch_func(1), plch_func(2) from dual',
                 dbms_sql.native);
  dbms_sql.define_column(c, 1, 1);
  rc := dbms_sql.execute_and_fetch(c);
  dbms_sql.close_cursor(c);
end;
/

ycpriscilla

A,B吧，后面实在不懂。。。帮顶

xhr8334

ABD。不过说真心话，D是试验出来的，AB是肯定可以。但是不明白C和D之间的区别。

xhr8334

为什么有into就能显示输出结果，没有into就不显示呢。。。求解释。。。

周应侯

这个是好东西啊，建议弄成ptf

魔界卧龙

一个个的试，不过好多不懂啊